Structure de boucle dans gnuplot ?

Question

Existe-t-il un moyen de récupérer itérativement les données de plusieurs fichiers et de les tracer sur le même graphique dans gnuplot. Supposons que j'ai des fichiers comme data1.txt, data2.txt......data1000.txt ; chacun ayant le même nombre de colonnes. Maintenant je pourrais écrire quelque chose comme-

plot "data1.txt" using 1:2 title "Flow 1", \
     "data2.txt" using 1:2 title "Flow 2", \
      .
      .
      .
     "data1000.txt"  using 1:2 title "Flow 6"

Mais ce serait vraiment gênant. Je me demandais s'il n'y avait pas un moyen de faire une boucle à travers le fichier parcelle dans gnuplot.

Answer 1

Il existe bien sûr (dans gnuplot 4.4+) :

plot for [i=1:1000] 'data'.i.'.txt' using 1:2 title 'Flow '.i

La variable i peut être interprétée comme une variable ou une chaîne de caractères, donc vous pourriez faire quelque chose comme

plot for [i=1:1000] 'data'.i.'.txt' using 1:($2+i) title 'Flow '.i

si vous voulez que les lignes soient décalées les unes par rapport aux autres.

Type help iteration à la ligne de commande de gnuplot pour plus d'informations.

Answer 2

Jetez également un coup d'œil à la do { ... } depuis gnuplot 4.6 car elle est très puissante :

do for [t=0:50] {
  outfile = sprintf('animation/bessel%03.0f.png',t)
  set output outfile
  splot u*sin(v),u*cos(v),bessel(u,t/50.0) w pm3d ls 1
}

http://www.gnuplotting.org/gnuplot-4-6-do/

Answer 3

J'ai le script tout.p

set ...
...
list=system('ls -1B *.dat')
plot for [file in list] file w l u 1:2 t file

Ici, les deux dernières lignes sont littérales et non heuristiques. Ensuite, j'exécute

$ gnuplot -p all.p

Changement *.dat au type de fichier que vous avez, ou ajouter des types de fichiers.

Prochaine étape : Ajoutez à ~/.bashrc cette ligne

alias p='gnuplot -p ~/./all.p'

et mettez votre fichier all.p dans votre répertoire personnel et voilà. Vous pouvez tracer tous les fichiers de n'importe quel répertoire en tapant p et enter.

EDITAR J'ai changé la commande, car ça ne marchait pas. Auparavant, elle contenait list(i)=word(system(ls -1B *.dat),i) .

Answer 4

Utilisez les éléments suivants si vous avez des colonnes discrètes à tracer dans un graphique

do for [indx in "2 3 7 8"] {
  column = indx + 0
  plot ifile using 1:column ;  
}

Answer 5

Je voulais utiliser des caractères génériques pour tracer plusieurs fichiers souvent placés dans des répertoires différents, tout en travaillant à partir de n'importe quel répertoire. La solution que j'ai trouvée a été de créer la fonction suivante dans le fichier ~/.bashrc

plo () {
local arg="w l"
local str="set term wxt size 900,500 title 'wild plotting'
set format y '%g'
set logs
plot"
while [ $# -gt 0 ]
        do str="$str '$1' $arg,"
        shift
done
echo "$str" | gnuplot -persist
}

et l'utiliser, par exemple, comme plo *.dat ../../dir2/*.out pour tracer tous les .dat dans le répertoire courant et tous les fichiers .out dans un répertoire qui se trouve être un niveau au-dessus et qui s'appelle dir2 .