Déboguer le code GLSL dans webgl

Question

Est-il possible de déboguer le code GLSL ou d'imprimer les valeurs des variables à l'intérieur du code glsl tout en l'utilisant avec webgl ? Les fichiers three.js ou scene.js contiennent-ils une telle fonctionnalité ?

Answer 1

Pas vraiment,

La façon dont je débogue habituellement GLSL est d'afficher les couleurs. Par exemple, avec 2 shaders comme

// vertex shader
uniform mat4 worldViewProjection;
uniform vec3 lightWorldPos;
uniform mat4 world;
uniform mat4 viewInverse;
uniform mat4 worldInverseTranspose;
attribute vec4 position;
attribute vec3 normal;
attribute vec2 texCoord;
varying vec4 v_position;
varying vec2 v_texCoord;
varying vec3 v_normal;
varying vec3 v_surfaceToLight;
varying vec3 v_surfaceToView;
void main() {
  v_texCoord = texCoord;
  v_position = (worldViewProjection * position);
  v_normal = (worldInverseTranspose * vec4(normal, 0)).xyz;
  v_surfaceToLight = lightWorldPos - (world * position).xyz;
  v_surfaceToView = (viewInverse[3] - (world * position)).xyz;
  gl_Position = v_position;
}

// fragment-shader    
precision highp float;

uniform vec4 colorMult;
varying vec4 v_position;
varying vec2 v_texCoord;
varying vec3 v_normal;
varying vec3 v_surfaceToLight;
varying vec3 v_surfaceToView;

uniform sampler2D diffuseSampler;
uniform vec4 specular;
uniform sampler2D bumpSampler;
uniform float shininess;
uniform float specularFactor;

vec4 lit(float l ,float h, float m) {
  return vec4(1.0,
              max(l, 0.0),
              (l > 0.0) ? pow(max(0.0, h), m) : 0.0,
              1.0);
}
void main() {
  vec4 diffuse = texture2D(diffuseSampler, v_texCoord) * colorMult;
  vec3 normal = normalize(v_normal);
  vec3 surfaceToLight = normalize(v_surfaceToLight);
  vec3 surfaceToView = normalize(v_surfaceToView);
  vec3 halfVector = normalize(surfaceToLight + surfaceToView);
  vec4 litR = lit(dot(normal, surfaceToLight),
                    dot(normal, halfVector), shininess);
  gl_FragColor = vec4((
  vec4(1,1,1,1) * (diffuse * litR.y
                        + specular * litR.z * specularFactor)).rgb,
      diffuse.a);
}

Si je ne voyais rien à l'écran, je changerais d'abord le fragment shader en ajoutant simplement une ligne à la fin

gl_FragColor = vec4(1,0,0,1);  // draw red

Si je commençais à voir ma géométrie, je saurais que le problème se situe probablement dans le fragment shader. Je pourrais vérifier mes normales en faisant ceci

gl_FragColor = vec4(v_normal * 0.5 + 0.5, 1);

Si les normales semblent correctes, je pourrais vérifier les coordonnées des UV avec

gl_FragColor = vec4(v_texCoord, 0, 1);

etc...

Answer 2

Vous pouvez essayer WebGL-Inspector à cette fin.