Comment changer le schéma de la base de données en dbo ?

Question

J'ai importé un certain nombre de tables d'un ancien serveur sql (2000) vers ma base de données 2008. Toutes les tables importées sont préfixées avec mon nom d'utilisateur, par exemple : jonathan.MovieData . Dans le tableau properties il énumère jonathan comme schéma de la base de données. Lorsque j'écris des procédures stockées, je dois maintenant inclure jonathan. devant tous les noms de tables, ce qui est déroutant.

Comment puis-je changer toutes mes tables en dbo au lieu de jonathan ?

Résultat actuel : jonathan.MovieData

Résultat souhaité : dbo.MovieData

Answer 1

ALTER SCHEMA dbo TRANSFER jonathan.MovieData;

Voir ALTER SCHEMA .

Syntaxe généralisée :

ALTER SCHEMA TargetSchema TRANSFER SourceSchema.TableName;

Answer 2

Vous pouvez exécuter la commande suivante, qui générera un ensemble d'instructions ALTER sCHEMA pour tous vos talbes :

SELECT 'ALTER SCHEMA dbo TRANSFER ' + TABLE_SCHEMA + '.' + TABLE_NAME 
FROM INFORMATION_SCHEMA.TABLES WHERE TABLE_SCHEMA = 'jonathan'

Vous devez ensuite copier et exécuter les déclarations dans l'analyseur de requêtes.

Voici un ancien script qui le fera aussi pour vous, je pense en changeant le propriétaire de l'objet. Je ne l'ai pas essayé sur 2008, cependant.

DECLARE @old sysname, @new sysname, @sql varchar(1000)

SELECT
  @old = 'jonathan'
  , @new = 'dbo'
  , @sql = '
  IF EXISTS (SELECT NULL FROM INFORMATION_SCHEMA.TABLES
  WHERE
      QUOTENAME(TABLE_SCHEMA)+''.''+QUOTENAME(TABLE_NAME) = ''?''
      AND TABLE_SCHEMA = ''' + @old + '''
  )
  EXECUTE sp_changeobjectowner ''?'', ''' + @new + ''''

EXECUTE sp_MSforeachtable @sql

Je l'ai obtenu de ce site .

Il est également question de faire la même chose pour les procs stockés si vous en avez besoin.

Answer 3

USE MyDB;
GO
ALTER SCHEMA dbo TRANSFER jonathan.MovieData;
GO

Réf : ALTER SCHEMA

Answer 4

Déplacer la table de dbo schema vers MySchema :

 ALTER SCHEMA MySchema TRANSFER dbo.MyTable

Déplacer la table de MySchema vers le schéma dbo :

 ALTER SCHEMA dbo TRANSFER MySchema.MyTable

Answer 5

Je viens de poster ceci à une question similaire : Dans sql server 2005, comment modifier le "schéma" d'une table sans perdre de données ?

---

A léger amélioration de l'excellente réponse de sAeid...

J'ai ajouté un exec pour que ce code s'exécute lui-même, et j'ai ajouté une union en haut pour pouvoir modifier le schéma des tables ET des procédures stockées :

DECLARE cursore CURSOR FOR 

select specific_schema as 'schema', specific_name AS 'name'
FROM INFORMATION_SCHEMA.routines
WHERE specific_schema <> 'dbo' 

UNION ALL

SELECT TABLE_SCHEMA AS 'schema', TABLE_NAME AS 'name'
FROM INFORMATION_SCHEMA.TABLES 
WHERE TABLE_SCHEMA <> 'dbo' 

DECLARE @schema sysname, 
 @tab sysname, 
 @sql varchar(500) 

OPEN cursore     
FETCH NEXT FROM cursore INTO @schema, @tab 

WHILE @@FETCH_STATUS = 0     
BEGIN 
 SET @sql = 'ALTER SCHEMA dbo TRANSFER [' + @schema + '].[' + @tab +']'    
 PRINT @sql   
 exec (@sql)  
 FETCH NEXT FROM cursore INTO @schema, @tab     
END 

CLOSE cursore     
DEALLOCATE cursore

Moi aussi, j'ai dû restaurer un dbdump, et j'ai découvert que le schéma n'était pas dbo - j'ai passé des heures à essayer de faire en sorte que Sql Server management studio ou visual studio data transfers modifie le schéma de destination... J'ai fini par exécuter ceci contre le dump restauré sur le nouveau serveur pour obtenir les choses comme je le voulais.