Comment puis-je obtenir la date et l'heure actuelles sur la ligne de commande Windows dans un format approprié pour être utilisé dans un nom de fichier/dossier ?

Question

Mise à jour : Maintenant que nous sommes en 2016, j'utiliserais PowerShell pour cela, à moins qu'il n'y ait une raison de rétrocompatibilité vraiment convaincante, notamment en raison du problème des paramètres régionaux avec l'utilisation de date . Voir @npocmaka's https://stackoverflow.com/a/19799236/8479

---

Quelle(s) instruction(s) de ligne de commande Windows puis-je utiliser pour obtenir l'heure actuelle dans un format que je peux mettre dans un nom de fichier ?

Je veux avoir un fichier .bat qui zippe un répertoire dans une archive avec la date et l'heure actuelles dans le nom, par exemple, Code_2008-10-14_2257.zip . Existe-t-il un moyen simple de le faire, indépendamment des paramètres régionaux de la machine ?

Le format de la date ne me dérange pas vraiment, l'idéal étant que ce soit aaaa-mm-jj, mais tout ce qui est simple me convient.

Jusqu'à présent, j'ai obtenu ceci, ce qui sur ma machine me donne Tue_10_14_2008_230050_91 :

rem Get the datetime in a format that can go in a filename.
set _my_datetime=%date%_%time%
set _my_datetime=%_my_datetime: =_%
set _my_datetime=%_my_datetime::=%
set _my_datetime=%_my_datetime:/=_%
set _my_datetime=%_my_datetime:.=_%

rem Now use the timestamp by in a new ZIP file name.
"d:\Program Files\7-Zip\7z.exe" a -r Code_%_my_datetime%.zip Code

Je peux vivre avec ça, mais ça semble un peu lourd. L'idéal serait qu'elle soit plus brève et qu'elle ait le format mentionné plus haut.

J'utilise Windows Server 2003 et Windows XP Professional. Je ne souhaite pas installer d'utilitaires supplémentaires pour y parvenir (bien que je sache qu'il en existe qui permettent un formatage agréable des dates).

Answer 1

Les quatre premières lignes de ce code vous donneront des variables fiables YY DD MM YYYY HH Min Sec sous Windows XP Professional et supérieur.

@echo off
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%"

set "datestamp=%YYYY%%MM%%DD%" & set "timestamp=%HH%%Min%%Sec%" & set "fullstamp=%YYYY%-%MM%-%DD%_%HH%%Min%-%Sec%"
echo datestamp: "%datestamp%"
echo timestamp: "%timestamp%"
echo fullstamp: "%fullstamp%"
pause

Answer 2

Malheureusement, ce système n'est pas insensible aux paramètres régionaux, mais il fait ce que vous voulez.

set hour=%time:~0,2%
if "%time:~0,1%"==" " set hour=0%time:~1,1%
set _my_datetime=%date:~10,4%-%date:~4,2%-%date:~7,2%_%hour%%time:~3,2%

C'est incroyable tout ce qu'on peut trouver sur Wikipedia .

Answer 3

Veuillez utiliser le script suivant pour obtenir le jour actuel dans la ligne de commande :

echo %Date:~0,3%day

Answer 4

"d:\Program Files\7-Zip\7z.exe" a -r code_%date:~10,4%-%date:~4,2%-%date:~7,2%.zip

Answer 5

Une autre façon ( crédit ):

@For /F "tokens=2,3,4 delims=/ " %%A in ('Date /t') do @( 
    Set Month=%%A
    Set Day=%%B
    Set Year=%%C
)

@echo DAY = %Day%
@echo Month = %Month%
@echo Year = %Year%

Notez que mes deux réponses dépendent toujours de l'ordre du jour et du mois tel que déterminé par les paramètres régionaux - je ne sais pas comment contourner cela.