Existe-t-il un équivalent de "which" dans la ligne de commande Windows ?

Question

Comme j'ai parfois des problèmes de chemin, où l'un de mes propres scripts cmd est caché (shadowé) par un autre programme (plus tôt sur le chemin), j'aimerais être capable de trouver le chemin complet d'un programme sur la ligne de commande Windows, étant donné seulement son nom.

Existe-t-il un équivalent de la commande UNIX "which" ?

Sous UNIX, which command imprime le chemin complet de la commande donnée pour trouver et réparer facilement ces problèmes d'ombrage.

Answer 1

Windows Server 2003 et les versions ultérieures (c'est-à-dire tout ce qui est postérieur à Windows XP 32 bits) fournissent les fonctionnalités suivantes where.exe qui fait une partie de ce que which le fait, bien qu'il corresponde à tous les types de fichiers, et pas seulement aux commandes exécutables. (Elle ne correspond pas aux commandes intégrées de l'interpréteur de commandes comme cd .) Il accepte même les caractères de remplacement, ainsi where nt* trouve tous les fichiers dans votre %PATH% et le répertoire courant dont le nom commence par nt .

Essayez where /? pour de l'aide.

Notez que Windows PowerShell définit where comme un alias pour le site Where-Object cmdlet donc si vous voulez where.exe vous devez taper le nom complet au lieu d'omettre l'élément d'identification. .exe extension. Vous pouvez également lui attribuer un alias :

Set-Alias which where.exe

Mise à jour : Utilisation de Get-Command (alias : gcm ) est recommandé car il est natif de PS et récupère tous les types de commandes : alias, cmdlets, exécutables et fonctions. Exemple :

gcm notepad*

Answer 2

Alors que les versions ultérieures de Windows ont un where vous pouvez également le faire avec Windows XP en utilisant les modificateurs de variables d'environnement, comme suit :

c:\> for %i in (cmd.exe) do @echo.   %~$PATH:i
   C:\WINDOWS\system32\cmd.exe

c:\> for %i in (python.exe) do @echo.   %~$PATH:i
   C:\Python25\python.exe

Vous n'avez pas besoin d'outils supplémentaires et il n'est pas limité à PATH puisque vous pouvez substituer n'importe quelle variable d'environnement (au format chemin d'accès, bien sûr) que vous souhaitez utiliser.

---

Et, si vous en voulez un qui peut gérer toutes les extensions dans PATHEXT (comme le fait Windows lui-même), celui-ci fait l'affaire :

@echo off
setlocal enableextensions enabledelayedexpansion

:: Needs an argument.

if "x%1"=="x" (
    echo Usage: which ^<progName^>
    goto :end
)

:: First try the unadorned filenmame.

set fullspec=
call :find_it %1

:: Then try all adorned filenames in order.

set mypathext=!pathext!
:loop1
    :: Stop if found or out of extensions.

    if "x!mypathext!"=="x" goto :loop1end

    :: Get the next extension and try it.

    for /f "delims=;" %%j in ("!mypathext!") do set myext=%%j
    call :find_it %1!myext!

:: Remove the extension (not overly efficient but it works).

:loop2
    if not "x!myext!"=="x" (
        set myext=!myext:~1!
        set mypathext=!mypathext:~1!
        goto :loop2
    )
    if not "x!mypathext!"=="x" set mypathext=!mypathext:~1!

    goto :loop1
:loop1end

:end
endlocal
goto :eof

:: Function to find and print a file in the path.

:find_it
    for %%i in (%1) do set fullspec=%%~$PATH:i
    if not "x!fullspec!"=="x" @echo.   !fullspec!
    goto :eof

Il renvoie en fait toutes les possibilités, mais vous pouvez le modifier assez facilement pour des règles de recherche spécifiques.

Answer 3

Dans Windows PowerShell :

set-alias which where.exe

Answer 4

Si vous avez installé PowerShell (ce que je recommande), vous pouvez utiliser la commande suivante comme équivalent approximatif (remplacez programName par le nom de votre exécutable) :

($Env:Path).Split(";") | Get-ChildItem -filter programName*

La suite est ici : Mon Manwich ! PowerShell qui

Answer 5

El GnuWin32 les outils ont which ainsi qu'un grand nombre d'autres outils Unix.