UltiSnips et YouCompleteMe

Question

J'ai les bundles ultisnips et youcompleteme installés sur mon macvim. Le problème est que ultisnips ne fonctionne pas parce que tab est lié par ycm. J'ai essayé de mettre let g:UltiSnipsExpandTrigger = "<s-tab>" afin de pouvoir déclencher l'achèvement du snippet avec shift-tab, mais cela ne fonctionne pas pour une raison inconnue. Je pourrais utiliser les majuscules comme déclencheur, mais jusqu'à présent, je n'ai trouvé aucun moyen de le faire.

L'un d'entre vous utilise-t-il ces deux modules complémentaires ensemble ? Que puis-je faire pour que shift-tab fonctionne ? Pouvez-vous me recommander une autre touche pour déclencher les snippets ?

Answer 1

Une autre option consiste à utiliser le plugin SuperTab :

" if you use Vundle, load plugins:
Bundle 'ervandew/supertab'
Bundle 'Valloric/YouCompleteMe'
Bundle 'SirVer/ultisnips'

" make YCM compatible with UltiSnips (using supertab)
let g:ycm_key_list_select_completion = ['<C-n>', '<Down>']
let g:ycm_key_list_previous_completion = ['<C-p>', '<Up>']
let g:SuperTabDefaultCompletionType = '<C-n>'

" better key bindings for UltiSnipsExpandTrigger
let g:UltiSnipsExpandTrigger = "<tab>"
let g:UltiSnipsJumpForwardTrigger = "<tab>"
let g:UltiSnipsJumpBackwardTrigger = "<s-tab>"

Ici YouCompleteMe est lié à une combinaison différente Ctrln mais cette combinaison est liée à l'onglet par le biais de SuperTab. UltiSnips et SuperTab fonctionnent bien ensemble, vous pouvez donc lier directement UltiSnips à Tab et tout se passera bien.

Answer 2

Essayez cette suggestion sur un page de l'outil de suivi des problèmes de YouCompleteMe. Dans votre .vimrc :

let g:UltiSnipsExpandTrigger="<c-j>"

Alors que ce paramètre rendra l'expansion d'un extrait partager le mappage par défaut pour sauter en avant dans un extrait Il simule le comportement de TextMates tel que mentionné dans les balises d'aide d'UltiSnips.

Comme j'ai associé ma touche de verrouillage des majuscules à la touche Ctrl, cette association fonctionne sans problème.

Answer 3

Copiez le code suivant dans votre vimrc, et profitez-en. Cette fonction gérera tous les problèmes entre YCM et UltiSnips.

function! g:UltiSnips_Complete()
    call UltiSnips#ExpandSnippet()
    if g:ulti_expand_res == 0
        if pumvisible()
            return "\<C-n>"
        else
            call UltiSnips#JumpForwards()
            if g:ulti_jump_forwards_res == 0
               return "\<TAB>"
            endif
        endif
    endif
    return ""
endfunction

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsExpandTrigger . " <C-R>=g:UltiSnips_Complete()<cr>"
let g:UltiSnipsJumpForwardTrigger="<tab>"
let g:UltiSnipsListSnippets="<c-e>"
" this mapping Enter key to <C-y> to chose the current highlight item 
" and close the selection list, same as other IDEs.
" CONFLICT with some plugins like tpope/Endwise
inoremap <expr> <CR> pumvisible() ? "\<C-y>" : "\<C-g>u\<CR>"

Answer 4

J'ai ceci dans mon vimrc

"" YouCompleteMe
let g:ycm_key_list_previous_completion=['<Up>']

"" Ultisnips
let g:UltiSnipsExpandTrigger="<c-tab>"
let g:UltiSnipsListSnippets="<c-s-tab>"

c'est ce que j'ai fait lors de mon premier essai, mais j'ai mal écrit UltiSnips avec Ultisnips oh bien, ça a marché à la fin !

Answer 5

Bien que je sache que ce post est un peu vieux, j'ai ma propre fonction qui est un peu plus optimisée que celle donnée ci-dessus :

function! g:UltiSnips_Complete()
  call UltiSnips#ExpandSnippetOrJump()
  if g:ulti_expand_or_jump_res == 0
    if pumvisible()
      return "\<C-N>"
    else
      return "\<TAB>"
    endif
  endif

  return ""
endfunction

Bien sûr, si vous conservez les paramètres fournis par Joey Liu et que vous utilisez cette fonction, tout fonctionnera parfaitement !

EDIT : Aussi, j'utilise une autre fonction pour augmenter la fonctionnalité de back-stepping entre YouCompleteMe et UltiSnips. Je vais vous montrer ce que je veux dire :

function! g:UltiSnips_Reverse()                                                                                               
  call UltiSnips#JumpBackwards()                                                                                              
  if g:ulti_jump_backwards_res == 0        
    return "\<C-P>"                                                                                                           
  endif                                                                                                                       

  return ""                                                                                                                   
endfunction

Ensuite, il suffit de mettre ceci dans votre .vimrc :

au BufEnter * exec "inoremap <silent> " . g:UltiSnipsJumpBackwardTrigger . " <C-R>=g:UltiSnips_Reverse()<cr>"

Ainsi que let g:UltiSnipsJumpBackwardTrigger="<s-tab>" et votre plateau !