Inno Setup : Comment désinstaller automatiquement la version précédemment installée ?

Question

J'utilise Inno Setup pour créer un programme d'installation.

Je veux que le programme d'installation désinstalle automatiquement la version installée précédemment, au lieu de l'écraser. Comment puis-je faire cela ?

Answer 1

J'ai utilisé la méthode suivante. Je ne suis pas sûr que ce soit la façon la plus simple de procéder, mais cela fonctionne.

Cela utilise {#emit SetupSetting("AppId")} qui s'appuie sur le préprocesseur Inno Setup. Si vous ne l'utilisez pas, copiez et collez votre App ID directement.

[Code]

{ ///////////////////////////////////////////////////////////////////// }
function GetUninstallString(): String;
var
  sUnInstPath: String;
  sUnInstallString: String;
begin
  sUnInstPath := ExpandConstant('Software\Microsoft\Windows\CurrentVersion\Uninstall\{#emit SetupSetting("AppId")}_is1');
  sUnInstallString := '';
  if not RegQueryStringValue(HKLM, sUnInstPath, 'UninstallString', sUnInstallString) then
    RegQueryStringValue(HKCU, sUnInstPath, 'UninstallString', sUnInstallString);
  Result := sUnInstallString;
end;

{ ///////////////////////////////////////////////////////////////////// }
function IsUpgrade(): Boolean;
begin
  Result := (GetUninstallString() <> '');
end;

{ ///////////////////////////////////////////////////////////////////// }
function UnInstallOldVersion(): Integer;
var
  sUnInstallString: String;
  iResultCode: Integer;
begin
{ Return Values: }
{ 1 - uninstall string is empty }
{ 2 - error executing the UnInstallString }
{ 3 - successfully executed the UnInstallString }

  { default return value }
  Result := 0;

  { get the uninstall string of the old app }
  sUnInstallString := GetUninstallString();
  if sUnInstallString <> '' then begin
    sUnInstallString := RemoveQuotes(sUnInstallString);
    if Exec(sUnInstallString, '/SILENT /NORESTART /SUPPRESSMSGBOXES','', SW_HIDE, ewWaitUntilTerminated, iResultCode) then
      Result := 3
    else
      Result := 2;
  end else
    Result := 1;
end;

{ ///////////////////////////////////////////////////////////////////// }
procedure CurStepChanged(CurStep: TSetupStep);
begin
  if (CurStep=ssInstall) then
  begin
    if (IsUpgrade()) then
    begin
      UnInstallOldVersion();
    end;
  end;
end;

Alternatives

Voir aussi ce billet de blog "Inno Setup script Echantillon pour la comparaison des versions" qui va un peu plus loin, et lit le numéro de version de toute version précédemment installée, et compare ce numéro de version avec celui du paquet d'installation actuel.

Answer 2

Vous devriez être capable de lire la chaîne de désinstallation à partir du registre, étant donné l'AppId (c'est-à-dire la valeur que vous avez utilisé pour AppID dans le [Setup] -). Il peut être trouvé sous Software\Microsoft\Windows\CurrentVersion\Uninstall\{AppId}\ (peut être soit HKLM ou HKCU il est donc préférable de vérifier les deux) où {AppId} doit être remplacé par la valeur réelle que vous avez utilisée. Recherchez l'icône UninstallString ou QuietUninstallString et utiliser les Exec pour l'exécuter à partir de votre InitializeSetup() fonction d'événement.

Answer 3

Si vous voulez "juste supprimer les anciennes icônes" (parce que les vôtres ont été modifiées/mises à jour), vous pouvez utiliser ceci :

; attempt to remove previous versions' icons
[InstallDelete]
Type: filesandordirs; Name: {group}\*;

Cette opération est exécutée "au début de l'installation" et supprime les anciennes icônes. Les nouvelles icônes seront toujours installées une fois l'opération terminée.

Je fais cela à chaque installation "au cas où quelque chose aurait changé" au niveau des icônes (tout est réinstallé de toute façon).

Answer 4

Lorsque vous utilisez Inno Setup, il n'y a aucune raison de désinstaller une version précédente, sauf si cette version a été installée par un programme d'installation différent. Sinon, les mises à jour sont gérées automatiquement.

Answer 5

La réponse fournie par Craig McQueen est tout à fait viable. Cependant, j'ajouterais ces commentaires :

• Le site {#emit SetupSetting("AppId")} ne fonctionne pas pour moi, donc j'ajoute juste mon App ID.
• Je ne voulais pas exécuter mon programme de désinstallation, car j'ai un fichier de configuration INI stocké dans le dossier AppData/ qui est supprimé par le désinstalleur, et je ne veux pas qu'il soit effacé lors de l'installation d'une nouvelle version. J'ai donc modifié un peu le code fourni par Craig McQueen pour supprimer le répertoire où est installé le programme, après avoir récupéré son chemin.

Donc, en ce qui concerne le code de Craig McQueen, les changements sont :

• Récupérer le InstallLocation au lieu de la touche UninstallString clé.
• Utilisez le DelTree au lieu de la fonction Exec(sUnInstallString, ...)