Comment savoir si une variable a une valeur numérique en Perl ?

Question

Existe-t-il un moyen simple en Perl qui me permette de déterminer si une variable donnée est numérique ? Je ne sais pas si c'est le cas, mais c'est une bonne idée :

if (is_number($x))
{ ... }

serait idéal. Une technique qui n'émettra pas d'avertissement lorsque le -w L'utilisation d'un commutateur est certainement préférable.

Answer 1

Utilice Scalar::Util::looks_like_number() qui utilise la fonction looks_like_number() de l'API Perl C, ce qui est probablement la façon la plus efficace de procéder. Notez que les chaînes "inf" et "infinity" sont traitées comme des nombres.

Exemple :

#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

Donne ce résultat :

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number

Voir aussi

• perldoc Scalar::Util
• perldoc perlapi pour looks_like_number

Answer 2

La question initiale était de savoir si une variable était numérique, et non si elle "avait une valeur numérique".

Certains opérateurs ont des modes de fonctionnement distincts pour les opérandes numériques et les opérandes de type chaîne de caractères, le terme "numérique" désignant tout ce qui était à l'origine un nombre ou qui a été utilisé dans un contexte numérique (par exemple dans $x = "123"; 0+$x avant l'ajout, $x est une chaîne de caractères, il est ensuite considéré comme numérique).

Voici un moyen de le savoir :

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

Si la fonction "bitwise" est activée, cela signifie que & n'est qu'un opérateur numérique et ajoute une chaîne de caractères distincte &. vous devez le désactiver :

if ( length( do { no if $] >= 5.022, "feature", "bitwise"; no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

(bitwise est disponible dans perl 5.022 et plus, et activé par défaut si vous utilisez la fonction use 5.028; ou plus).

Answer 3

Consultez le module CPAN Regexp::Common . Je pense qu'il fait exactement ce dont vous avez besoin et qu'il gère tous les cas particuliers (par exemple, les nombres réels, la notation scientifique, etc.

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }

Answer 4

En général, la validation des nombres se fait à l'aide d'expressions régulières. Ce code déterminera si quelque chose est numérique et vérifiera qu'il n'y a pas de variables indéfinies afin de ne pas générer d'avertissements :

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

En voici quelques-uns matériel de lecture que vous devriez consulter.

Answer 5

Une réponse simple (et peut-être simpliste) à la question est le contenu de $x numérique est la suivante :

if ($x  eq  $x+0) { .... }

Il procède à une comparaison textuelle de l'original $x avec le $x converti en valeur numérique.