Convertit serial.read () en une chaîne utilisable avec Arduino?

Question

J'utilise deux Arduinos pour envoyer des chaînes de texte en clair à l'aide de newsoftserial et d'un émetteur-récepteur RF .

Chaque chaîne est peut-être 20-30 caractères de long. Comment convertir Serial.read() en chaîne afin de pouvoir faire if x == "testing statements" , etc.?

Answer 1

Chaîne illimitée lue

   String content = "";
  char character;

  while(Serial.available()) {
      character = Serial.read();
      content.concat(character);
  }

  if (content != "") {
    Serial.println(content);
  }
 

Answer 2

Dans l' aide sur Serial.Read () pour obtenir la chaîne :

 char inData[20]; // Allocate some space for the string
char inChar=-1; // Where to store the character read
byte index = 0; // Index into array; where to store the character

void setup() {
    Serial.begin(9600);
    Serial.write("Power On");
}

char Comp(char* This) {
    while (Serial.available() > 0) // Don't read unless
                                   // there you know there is data
    {
        if(index < 19) // One less than the size of the array
        {
            inChar = Serial.read(); // Read a character
            inData[index] = inChar; // Store it
            index++; // Increment where to write next
            inData[index] = '\0'; // Null terminate the string
        }
    }

    if (strcmp(inData,This)  == 0) {
        for (int i=0;i<19;i++) {
            inData[i]=0;
        }
        index=0;
        return(0);
    }
    else {
        return(1);
    }
}

void loop()
{
    if (Comp("m1 on")==0) {
        Serial.write("Motor 1 -> Online\n");
    }
    if (Comp("m1 off")==0) {
        Serial.write("Motor 1 -> Offline\n");
    }
}
 

Answer 3

Vous pouvez utiliser Serial.readString() et Serial.readStringUntil() pour analyser les chaînes de série sur l'Arduino.

Vous pouvez également utiliser Serial.parseInt() pour lire les valeurs entières de série.

 int x;
String str;

void loop() 
{
    if(Serial.available() > 0)
    {
        str = Serial.readStringUntil('\n');
        x = Serial.parseInt();
    }
}
 

La valeur à envoyer en série serait my string\n5 et le résultat serait str = "my string" et x = 5

Answer 4

Je posais moi-même la même question et après quelques recherches, j'ai trouvé quelque chose comme ça.

Cela fonctionne comme un charme pour moi. Je l'utilise pour contrôler à distance mon Arduino.

 // Buffer to store incoming commands from serial port
String inData;

void setup() {
    Serial.begin(9600);
    Serial.println("Serial conection started, waiting for instructions...");
}

void loop() {
    while (Serial.available() > 0)
    {
        char recieved = Serial.read();
        inData += recieved; 

        // Process message when new line character is recieved
        if (recieved == '\n')
        {
            Serial.print("Arduino Received: ");
            Serial.print(inData);

            // You can put some if and else here to process the message juste like that:

            if(inData == "+++\n"){ // DON'T forget to add "\n" at the end of the string.
              Serial.println("OK. Press h for help.");
            }   


            inData = ""; // Clear recieved buffer
        }
    }
}
 

Answer 5

Ce serait beaucoup plus facile:

  char data [21];
 int number_of_bytes_received;

 if(Serial.available() > 0)
 {
   number_of_bytes_received = Serial.readBytesUntil (13,data,20); // read bytes (max. 20) from buffer, untill <CR> (13). store bytes in data. count the bytes recieved.
   data[number_of_bytes_received] = 0; // add a 0 terminator to the char array
 } 

 bool result = strcmp (data, "whatever");
 // strcmp returns 0; if inputs match.
 // http://en.cppreference.com/w/c/string/byte/strcmp


 if (result == 0)
 {
   Serial.println("data matches whatever");
 } 
 else 
 {
   Serial.println("data does not match whatever");
 }