Clause de sortie du serveur SQL dans une variable scalaire

Question

Existe-t-il un moyen "simple" de faire cela ou dois-je passer par une variable de table avec la syntaxe "OUTPUT ... INTO" ?

DECLARE @someInt int

INSERT INTO MyTable2(AIntColumn)
OUTPUT @SomeInt = Inserted.AIntColumn
VALUES(12)

Answer 1

Vous avez besoin d'une variable de table et cela peut être aussi simple que cela.

declare @ID table (ID int)

insert into MyTable2(ID)
output inserted.ID into @ID
values (1)

Answer 2

Plus d'un an plus tard... si ce dont vous avez besoin est d'obtenir l'identifiant généré automatiquement d'une table, vous pouvez simplement

SELECT @ReportOptionId = SCOPE_IDENTITY()

Sinon, il semble que vous soyez obligé d'utiliser un tableau.

Answer 3

Bien plus tard, mais cela vaut la peine d'être mentionné, vous pouvez également utiliser des variables pour sortir des valeurs dans la clause SET d'un UPDATE ou dans les champs d'un SELECT ;

DECLARE @val1 int;
DECLARE @val2 int;
UPDATE [dbo].[PortalCounters_TEST]
SET @val1 = NextNum, @val2 = NextNum = NextNum + 1
WHERE [Condition] = 'unique value'
SELECT @val1, @val2

Dans l'exemple ci-dessus, @val1 a la valeur avant et @val2 a la valeur après, bien que je soupçonne que tout changement provenant d'un déclencheur ne serait pas dans val2, donc vous devriez utiliser la table de sortie dans ce cas. Pour tout autre cas que le cas le plus simple, je pense que le tableau de sortie sera plus lisible dans votre code également.

Cela peut s'avérer très utile si vous souhaitez transformer une colonne en une liste séparée par des virgules ;

DECLARE @list varchar(max) = '';
DECLARE @comma varchar(2) = '';
SELECT @list = @list + @comma + County, @comma = ', ' FROM County
print @list

Answer 4

Réponse :

Vous pouvez utiliser @@IDENTITY pour obtenir le dernier identifiant inséré.

DECLARE @someInt int
INSERT INTO MyTable2(AIntColumn)
VALUES(12)
SET @someInt = @@IDENTITY;

En supposant que votre table a une clé primaire que vous cherchez à définir comme ladite variable.

Exemple de schéma

CREATE TABLE MyTable2(
    [ID] [INT] IDENTITY(1,1),
    [aIntColumn] [INT]
)
CREATE TABLE MyTable3(
    [ID] [INT] IDENTITY(1,1),
    [newInt] [INT],
    [FK_int] [INT]
)

Vous pouvez ensuite l'utiliser dans la partie suivante de votre script, par ex.

DECLARE @someInt INT;
INSERT INTO MyTable2(AIntColumn)
VALUES(12)
SET @someInt = @@IDENTITY;

--do something else
DECLARE @someInt2 INT;
INSERT INTO MyTable3(newInt, FK_int)
VALUES(101, @someInt)
SET @someInt2 = @@IDENTITY;

SELECT @someInt AS 'First Inserted ID ',  @someInt2 AS 'Second inserted ID';