Dans CMake, comment puis-je tester si le compilateur est Clang ?

Question

Nous avons un ensemble de scripts de construction CMake multiplateforme et nous soutenons la construction avec Visual C++ et CCG .

Nous essayons Clang mais je n'arrive pas à trouver comment tester si le compilateur est Clang ou non avec notre CMake script.

Que dois-je tester pour savoir si le compilateur est Clang ou non ? Nous utilisons actuellement MSVC et CMAKE_COMPILER_IS_GNU<LANG> pour tester Visual C++ et GCC, respectivement.

Answer 1

Une vérification fiable consiste à utiliser le CMAKE_<LANG>_COMPILER_ID variables. Par exemple, pour vérifier le compilateur C++ :

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  # using Clang
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
  # using GCC
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "Intel")
  # using Intel C++
elseif (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  # using Visual Studio C++
endif()

Ceux-ci fonctionnent également correctement si un wrapper de compilateur comme ccache est utilisé.

À partir de CMake 3.0.0, l'option CMAKE_<LANG>_COMPILER_ID pour le Clang fourni par Apple est maintenant AppleClang . Pour tester à la fois le Clang fourni par Apple et le Clang normal, utilisez la condition if suivante :

if (CMAKE_CXX_COMPILER_ID MATCHES "Clang")
  # using regular Clang or AppleClang
endif()

Voir également le Description de la politique d'AppleClang .

CMake 3.15 a ajouté un support pour les deux clang-club et le frontal clang normal. Vous pouvez déterminer la variante du front-end en inspectant la variable CMAKE_CXX_COMPILER_FRONTEND_VARIANT :

if (CMAKE_CXX_COMPILER_ID STREQUAL "Clang")
  if (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "MSVC")
    # using clang with clang-cl front end
  elseif (CMAKE_CXX_COMPILER_FRONTEND_VARIANT STREQUAL "GNU")
    # using clang with regular front end
  endif()
endif()

Answer 2

Voici une réponse un peu plus détaillée pour les novices de cmake, modifiée à partir de la réponse de sakra. La version minimale de 3.1 semble être importante car elle change la façon dont CMake traite la chaîne citée "MSVC" (selon la politique CMP0054).

cmake_minimum_required(VERSION 3.1)
project(MyProject CXX)

if ("${CMAKE_CXX_COMPILER_ID}" MATCHES "Clang")
  MESSAGE("Clang")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "GNU")
  MESSAGE("GNU")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "Intel")
  MESSAGE("Intel")
elseif ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()

Answer 3

Si votre VERSION cmake_minimum_required est inférieure à 3.1, alors vous devez utiliser la variable citée pour déterminer le compilateur, si elle est associée à la variable STREQUAL la commande, c'est-à-dire

if ("${CMAKE_CXX_COMPILER_ID}" STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()

Ou, si vous n'aimez pas les citations, vous pouvez utiliser MATCHES commandement :

if (CMAKE_CXX_COMPILER_ID MATCHES "MSVC")
  MESSAGE("MSVC")
endif()

Et si vous spécifiez cmake_minimum_required VERSION >= 3.1, alors vous pouvez utiliser avec bonheur STREQUAL sans guillemets :

if (CMAKE_CXX_COMPILER_ID STREQUAL "MSVC")
  MESSAGE("MSVC")
endif()

le problème de la version 3.1 de cmake, est documenté ici : https://cmake.org/cmake/help/latest/policy/CMP0054.html

Answer 4

Afin d'éviter tout problème d'orthographe, j'utilise la comparaison insensible à la casse, par exemple :

string( TOLOWER "${CMAKE_CXX_COMPILER_ID}" COMPILER_ID )
if (COMPILER_ID STREQUAL "clang")
    set(IS_CLANG_BUILD true)
else ()
    set(IS_CLANG_BUILD false)
endif ()

Pour rendre la regex de MATCHES insensible à la casse, j'ai tout essayé ici sans succès (cela ne semble pas être supporté par CMake).

Answer 5

Le code source du moteur OGRE 3D utilise les éléments suivants vérifier :

if (CMAKE_CXX_COMPILER MATCHES ".*clang")
    set(CMAKE_COMPILER_IS_CLANGXX 1)
endif ()