Comment tuer toutes les connexions actuelles à une base de données SQL Server 2005 ?

Question

Je veux renommer une base de données, mais je continue à obtenir l'erreur "couldn't get exclusive lock" sur la base de données, ce qui implique qu'il y a une ou plusieurs connexions encore actives.

Comment puis-je tuer toutes les connexions à la base de données afin de pouvoir la renommer ?

Answer 1

La raison pour laquelle l'approche que Adam a suggéré ne fonctionne pas, c'est que pendant que vous bouclez sur les connexions actives, de nouvelles connexions peuvent être établies, et vous les manquerez. Vous pouvez utiliser l'approche suivante qui ne présente pas cet inconvénient :

-- set your current connection to use master otherwise you might get an error

use master
ALTER DATABASE YourDatabase SET SINGLE_USER WITH ROLLBACK IMMEDIATE 

--do you stuff here 

ALTER DATABASE YourDatabase SET MULTI_USER

Answer 2

Script pour accomplir ceci, remplacez 'DB_NAME' avec la base de données pour tuer toutes les connexions :

USE master
GO

SET NOCOUNT ON
DECLARE @DBName varchar(50)
DECLARE @spidstr varchar(8000)
DECLARE @ConnKilled smallint
SET @ConnKilled=0
SET @spidstr = ''

Set @DBName = 'DB_NAME'
IF db_id(@DBName) < 4
BEGIN
PRINT 'Connections to system databases cannot be killed'
RETURN
END
SELECT @spidstr=coalesce(@spidstr,',' )+'kill '+convert(varchar, spid)+ '; '
FROM master..sysprocesses WHERE dbid=db_id(@DBName)

IF LEN(@spidstr) > 0
BEGIN
EXEC(@spidstr)
SELECT @ConnKilled = COUNT(1)
FROM master..sysprocesses WHERE dbid=db_id(@DBName)
END

Answer 3

Tuez-le, et tuez-le par le feu :

USE master
go

DECLARE @dbname sysname
SET @dbname = 'yourdbname'

DECLARE @spid int
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname)
WHILE @spid IS NOT NULL
BEGIN
EXECUTE ('KILL ' + @spid)
SELECT @spid = min(spid) from master.dbo.sysprocesses where dbid = db_id(@dbname) AND spid > @spid
END

Answer 4

Utilisation de SQL Management Studio Express :

Dans l'arborescence de l'Explorateur d'objets, descendez sous Gestion jusqu'à "Activity Monitor" (si vous ne le trouvez pas, faites un clic droit sur le serveur de base de données et sélectionnez "Activity Monitor"). En ouvrant le Moniteur d'activité, vous pouvez voir toutes les informations sur les processus. Vous devriez être en mesure de trouver les verrous de la base de données qui vous intéresse et de les supprimer, ce qui supprimera également la connexion.

Vous devriez être en mesure de renommer après cela.

Answer 5

J'ai toujours utilisé :

ALTER DATABASE DB_NAME SET SINGLE_USER WITH ROLLBACK IMMEDIATE 
GO 
SP_RENAMEDB 'DB_NAME','DB_NAME_NEW'
Go 
ALTER DATABASE DB_NAME_NEW  SET MULTI_USER -- set back to multi user 
GO