Exécuter automatiquement une macro Excel lors d'un changement de cellule

Question

Comment puis-je exécuter automatiquement une macro Excel chaque fois qu'une valeur dans une cellule particulière change?

En ce moment, mon code de travail est le suivant :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Range("H5")) Is Nothing Then Macro
End Sub

où "H5" est la cellule particulière surveillée et Macro est le nom de la macro.

Y a-t-il un meilleur moyen?

Answer 1

Votre code est assez bon.

Cependant, soyez prudent, car votre appel à Range("H5") est une commande raccourcie vers Application.Range("H5"), qui est équivalent à Application.ActiveSheet.Range("H5"). Cela pourrait être correct, si les seules modifications sont des modifications faites par l'utilisateur - ce qui est le plus courant - mais il est possible que les valeurs des cellules de la feuille de calcul changent lorsqu'elle n'est pas la feuille active via des modifications programmatiques, par exemple en VBA.

À ce sujet, j'utiliserais Target.Worksheet.Range("H5"):

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Target.Worksheet.Range("H5")) Is Nothing Then Macro
End Sub

Ou vous pouvez utiliser Me.Range("H5"), si le gestionnaire d'événements est sur la page de code de la feuille de calcul en question (ce qui est généralement le cas) :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("H5")) Is Nothing Then Macro
End Sub

Answer 2

Gérez l'événement Worksheet_Change ou l'événement Workbook_SheetChange.

Les gestionnaires d'événements prennent un argument "Target As Range", vous pouvez donc vérifier si la plage qui change inclut la cellule qui vous intéresse.

Answer 3

J'ai passé beaucoup de temps à rechercher et à apprendre comment tout cela fonctionne, après avoir vraiment perturbé les déclencheurs d'événements. Comme il y avait tellement d'informations dispersées, j'ai décidé de partager tout ce que j'ai trouvé qui fonctionne, tout au même endroit, pas à pas comme suit :

1) Ouvrez l'Éditeur VBA, sous le Projet VBA (VotreNomDeClasseur.xlsm) ouvrez l'Objet Microsoft Excel et sélectionnez la Feuille à laquelle l'événement de changement sera lié.

2) La vue par défaut du code est "Général". Dans la liste déroulante en haut au milieu, sélectionnez "Feuille de calcul".

3) Private Sub Worksheet_SelectionChange y est déjà comme il se doit, ne le modifiez pas. Copiez/collez le code de Mike Rosenblum ci-dessus et changez la référence .Range à la cellule pour laquelle vous surveillez un changement (B3, dans mon cas). Ne placez pas encore votre Macro, cependant (j'ai enlevé le mot "Macro" après "Then") :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("H5")) Is Nothing Then
End Sub

ou dans la liste déroulante en haut à gauche, sélectionnez "Changer" et dans l'espace entre Private Sub et End Sub, collez If Not Intersect(Target, Me.Range("H5")) Is Nothing Then

4) À la ligne après "Then" désactivez les événements pour que lorsque vous appelez votre macro, cela ne déclenche pas d'événements et essaie de relancer ce Worksheet_Change dans un cycle sans fin qui fait planter Excel et/ou perturbe autrement tout :

Application.EnableEvents = False

5) Appelez votre macro

Call NomDeVotreMacro

6) Réactivez les événements pour que le prochain changement (et tous les autres événements) se déclenchent :

Application.EnableEvents = True

7) Terminez le bloc If et le Sub :

    End If
End Sub

Le code entier :

Private Sub Worksheet_Change(ByVal Target As Range)
    If Not Intersect(Target, Me.Range("B3")) Is Nothing Then
        Application.EnableEvents = False
        Call UpdateAndViewOnly
        Application.EnableEvents = True
    End If
End Sub

Cela permet d'éliminer le fait de mettre en marche/arrêt les événements dans les modules, ce qui crée des problèmes et permet simplement au changement de se déclencher, de désactiver les événements, d'exécuter votre macro et de réactiver les événements.

Answer 4

Je préfère cette façon, ne pas utiliser une cellule mais une plage

    Dim cell_to_test As Range, cells_changed As Range

    Set cells_changed = Target(1, 1)
    Set cell_to_test = Range( PLAGE_DE_CELULES_A_DETECTER )

    If Not Intersect(cells_changed, cell_to_test) Is Nothing Then 
       Macro
    End If

Answer 5

J'ai une cellule qui est liée à une base de données d'actions en ligne et mise à jour fréquemment. Je veux déclencher une macro chaque fois que la valeur de la cellule est mise à jour.

Je pense que c'est similaire à un changement de valeur de cellule par un programme ou toute mise à jour de données externe mais les exemples ci-dessus ne fonctionnent pas pour moi. Je pense que le problème vient du fait que les événements internes d'Excel ne sont pas déclenchés, mais c'est juste une supposition.

J'ai fait ce qui suit,

Private Sub Worksheet_Change(ByVal Target As Range) 
  If Not Intersect(Target, Target.Worksheets("Symboles").Range("$C$3")) Is Nothing Then
   'Exécuter la macro
End Sub