Comment créer un fichier vide dans emacs ?

Question

Comment puis-je créer un fichier vide à partir d'emacs, idéalement à l'intérieur d'un tampon ditd ?

Par exemple, je viens d'ouvrir un module Python en mode dired, j'ai créé un nouveau répertoire, je l'ai ouvert en mode dired, et je dois maintenant ajouter un fichier vide __init__.py dans le répertoire.

Si j'utilise C-x C-f __init__.py RET C-x C-s alors emacs ne crée pas le fichier car aucune modification n'a été apportée. Il faudrait que je tape dans le fichier, que je l'enregistre, que j'efface ma saisie et que je l'enregistre à nouveau pour que cela fonctionne.

Merci

Answer 1

Vous pouvez utiliser la commande tactile :

M-! touch __init__.py RET

Answer 2

Les travaux suivants :

C-x b \_\_init\_\_.py RET C-x C-w RET

Si vous êtes dans une mémoire tampon directe, le fichier sera enregistré dans le répertoire indiqué ici.

L'astuce consiste à créer d'abord un tampon vide en passant à un nom qui n'existe pas. Ensuite, on écrit le fichier.

Answer 3

Si vous voulez qu'Emacs traite tous les nouveaux fichiers comme modifiés, vous pouvez automatiser la solution comme ceci :

(add-hook 'find-file-hooks 'assume-new-is-modified)
(defun assume-new-is-modified ()
  (when (not (file-exists-p (buffer-file-name)))
    (set-buffer-modified-p t)))

Answer 4

Emacs ne vous permettra pas de sauvegarder un tampon à moins qu'il ne pense que son contenu a changé. Le plus rapide, mais peut-être pas le plus propre, est d'ouvrir le fichier en utilisant C-x C-f puis appuyez sur (disons) l'espace et le retour arrière, alors vous devriez être en mesure d'enregistrer un fichier sans contenu.

Il existe d'autres moyens de modifier l'indicateur "le tampon a été modifié", mais je ne pense pas qu'il y en ait un plus simple.

Answer 5

Voici une adaptation de dired-create-directory . Cela fonctionne de la même façon, donc en plus d'un nom de fichier simple, vous pouvez également spécifier de nouveaux répertoires parents (à créer sous le répertoire courant) pour le fichier (par exemple foo/bar/filename ).

(eval-after-load 'dired
  '(progn
     (define-key dired-mode-map (kbd "C-c n") 'my-dired-create-file)
     (defun my-dired-create-file (file)
       "Create a file called FILE.
If FILE already exists, signal an error."
       (interactive
        (list (read-file-name "Create file: " (dired-current-directory))))
       (let* ((expanded (expand-file-name file))
              (try expanded)
              (dir (directory-file-name (file-name-directory expanded)))
              new)
         (if (file-exists-p expanded)
             (error "Cannot create file %s: file exists" expanded))
         ;; Find the topmost nonexistent parent dir (variable `new')
         (while (and try (not (file-exists-p try)) (not (equal new try)))
           (setq new try
                 try (directory-file-name (file-name-directory try))))
         (when (not (file-exists-p dir))
           (make-directory dir t))
         (write-region "" nil expanded t)
         (when new
           (dired-add-file new)
           (dired-move-to-filename))))))