Comment changer le curseur entre les modes Normal et Insertion dans Vim ?

Question

J'aimerais savoir comment changer, si possible, le curseur dans Vim (en couleur, forme, etc.) en fonction du mode dans lequel on se trouve.

J'oublie constamment que je ne suis pas en mode Insertion et je commence à taper du code, ce qui entraîne toutes sortes de choses bizarres. Il serait utile qu'il y ait une sorte d'indication visuelle sur le curseur.

Answer 1

Ce qui suit fonctionne dans xterm, urxvt et d'autres émulateurs de terminal sous Linux ; iTerm2 sous macOS ; Git Bash avec ConEmu sous Windows ; et plus encore (voir les commentaires) :

let &t_SI = "\e[6 q"
let &t_EI = "\e[2 q"

" reset the cursor on start (for older versions of vim, usually not required)
augroup myCmds
au!
autocmd VimEnter * silent !echo -ne "\e[2 q"
augroup END

Autres options (remplacer le numéro après \e[ ):

Ps = 0  -> blinking block.
Ps = 1  -> blinking block (default).
Ps = 2  -> steady block.
Ps = 3  -> blinking underline.
Ps = 4  -> steady underline.
Ps = 5  -> blinking bar (xterm).
Ps = 6  -> steady bar (xterm).

---

Lorsque vous utilisez tmux il est important de l'utiliser comme cela (sans l'option \<Esc>Ptmux; escape). tmux gardera la trace de la forme correcte du curseur lorsque vous changez de fenêtre/panneau.

Si cela ne fonctionne pas pour vous, essayez soit de définir TERM=xterm-256color avant de démarrer tmux, ou ajoutez ceci à votre fichier .tmux.conf ( Merci @Steven Lu ):

set -ga terminal-overrides ',*:Ss=\E[%p1%d q:Se=\E[2 q'

Answer 2

Une approche populaire pour indiquer le passage du mode Insertion à l'autre est la suivante de basculer le cursorline qui permet de déterminer si la ligne courante de l'écran est mise en évidence (voir :help cursorline ):

:autocmd InsertEnter,InsertLeave * set cul!

ou, alternativement :

:autocmd InsertEnter * set cul
:autocmd InsertLeave * set nocul

Modifiez le CursorLine groupe de surbrillance pour modifier le style de la ligne du curseur à votre convenance (cf. :help :highlight et :help highlight-groups ).

Answer 3

Je ne sais pas si quelqu'un d'autre fait face à un retard après avoir frappé le Esc pour revenir au mode normal et afficher le curseur de bloc, mais si c'est le cas, c'est aussi la façon dont je le règle.

En fait, j'utilise iTerm2 et j'utilise Vim dans mon terminal sous macOS. En entrant en mode insertion, le curseur reste un bloc et c'est un peu déroutant de savoir si on est en mode insertion ou en mode normal.

Je voulais afficher une ligne fine comme curseur en mode insertion et revenir au bloc en mode normal comme le fait MacVim. Et pour ce faire, c'est assez simple, il suffit d'ajouter ceci à mon fichier .vimrc en tant que décrit ici :

let &t_SI = "\<Esc>]50;CursorShape=1\x7"
let &t_SR = "\<Esc>]50;CursorShape=2\x7"
let &t_EI = "\<Esc>]50;CursorShape=0\x7"

Mais comme vous pouvez le voir, il y a eu un retard lorsque vous avez frappé ESC pour quitter le mode insertion et revenir au mode normal et afficher à nouveau le bloc comme curseur. Pour résoudre ce problème, j'ai trouvé ceci :

set ttimeout
set ttimeoutlen=1
set ttyfast

Et maintenant ça marche plutôt bien comme vous pouvez le voir :

J'espère que cela pourra aider quelqu'un d'autre !

Answer 4

Si vous utilisez tmux y iTerm2 en macOS ,
ce qui suit fait passer le curseur d'un bloc à un curseur et met en surbrillance la ligne courante

if exists('$TMUX')
  let &t_SI = "\<Esc>Ptmux;\<Esc>\<Esc>]50;CursorShape=1\x7\<Esc>\\"
  let &t_EI = "\<Esc>Ptmux;\<Esc>\<Esc>]50;CursorShape=0\x7\<Esc>\\"
else
  let &t_SI = "\<Esc>]50;CursorShape=1\x7"
  let &t_EI = "\<Esc>]50;CursorShape=0\x7"
endif
:autocmd InsertEnter * set cul
:autocmd InsertLeave * set nocul

crédit : https://gist.github.com/andyfowler/1195581

Answer 5

Pour modifier la forme du curseur dans différents modes, vous pouvez ajouter ce qui suit dans votre fichier .vimrc fichier.

Pour le terminal GNOME (version 2.26) :

if has("autocmd")
  au InsertEnter * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape ibeam"
  au InsertLeave * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape block"
  au VimLeave * silent execute "!gconftool-2 --type string --set /apps/gnome-terminal/profiles/Default/cursor_shape ibeam"
endif

Si vous utilisez plus d'un profil dans le terminal GNOME, vous devrez peut-être l'adapter à vos profils.

Pour Konsole dans KDE4 :

let &t_SI = "\<Esc>]50;CursorShape=1\x7"
let &t_EI = "\<Esc>]50;CursorShape=0\x7"

Cela fonctionne avec plusieurs onglets et Windows.

Voir aussi : " Modifier la forme du curseur dans différents modes " sur Wiki d'astuces Vim .