Correspondance non gourmande (réticente) de regex dans sed ?

Question

J'essaie d'utiliser sed pour nettoyer des lignes d'URL afin d'extraire uniquement le domaine.

Donc de :

http://www.suepearson.co.uk/product/174/71/3816/

Je veux :

http://www.suepearson.co.uk/

(avec ou sans la barre oblique de fin, cela n'a pas d'importance)

J'ai essayé :

 sed 's|\(http:\/\/.*?\/\).*|\1|'

et (en échappant au quantificateur non grégaire)

sed 's|\(http:\/\/.*\?\/\).*|\1|'

mais je ne parviens pas à obtenir le quantificateur non gourmand ( ? ) pour fonctionner, de sorte qu'il finit toujours par correspondre à la chaîne entière.

Answer 1

Ni la regex Posix/GNU de base ni la regex Posix/GNU étendue ne reconnaissent le quantificateur non avide ; vous devez utiliser une regex ultérieure. Heureusement, la regex Perl pour ce contexte est assez facile à obtenir :

perl -pe 's|(http://.*?/).*|\1|'

Answer 2

Dans ce cas précis, vous pouvez faire le travail sans utiliser une regex non gourmande.

Essayez cette regex non gourmande [^/]* au lieu de .*? :

sed 's|\(http://[^/]*/\).*|\1|g'

Answer 3

Avec sed, j'implémente généralement une recherche non avide en cherchant tout ce qui n'est pas le séparateur jusqu'au séparateur :

echo "http://www.suon.co.uk/product/1/7/3/" | sed -n 's;\(http://[^/]*\)/.*;\1;p'

Sortie :

http://www.suon.co.uk

c'est :

• ne pas produire -n
• recherche, correspondance de motifs, remplacement et impression s/<pattern>/<replace>/p
• utiliser ; séparateur de commande de recherche au lieu de / pour faciliter la saisie des données s;<pattern>;<replace>;p
• retenir la correspondance entre les parenthèses \( ... \) accessible par la suite avec \1 , \2 ...
• match http://
• suivi de tout ce qui est entre parenthèses [] , [ab/] signifierait soit a ou b ou /
• premièrement ^ sur [] signifie not suivi de tout ce qui n'est pas la chose en question. []
• donc [^/] signifie tout sauf / caractère
• * est de répéter le groupe précédent afin [^/]* désigne les caractères sauf / .
• jusqu'à présent sed -n 's;\(http://[^/]*\) signifie chercher et se souvenir http:// suivi de tous les caractères sauf / et souviens-toi de ce que tu as trouvé
• nous voulons chercher jusqu'à la fin du domaine, alors arrêtez-vous sur le suivant. / alors ajoutez un autre / à la fin : sed -n 's;\(http://[^/]*\)/' mais nous voulons faire correspondre le reste de la ligne après le domaine, alors ajoutez .*
• maintenant le match retenu dans le groupe 1 ( \1 ) est le domaine, il faut donc remplacer la ligne correspondante par les éléments enregistrés dans le groupe \1 et imprimer : sed -n 's;\(http://[^/]*\)/.*;\1;p'

Si vous souhaitez également inclure une barre oblique inverse après le domaine, ajoutez une barre oblique inverse supplémentaire dans le groupe à retenir :

echo "http://www.suon.co.uk/product/1/7/3/" | sed -n 's;\(http://[^/]*/\).*;\1;p'

sortie :

http://www.suon.co.uk/

Answer 4

Sed ne supporte pas l'opérateur "non gourmand".

Vous devez utiliser l'opérateur "[]" pour exclure "/" de la correspondance.

sed 's,\(http://[^/]*\)/.*,\1,'

P.S. Il n'est pas nécessaire de mettre la barre oblique inversée "/".

Answer 5

Solution non gourmande pour plus d'un seul caractère

Ce fil est vraiment vieux mais je suppose que les gens en ont encore besoin. Disons que vous voulez tout tuer jusqu'à la toute première occurrence de HELLO . Vous ne pouvez pas dire [^HELLO] ...

Ainsi, une bonne solution implique deux étapes, en supposant que vous pouvez épargner un mot unique que vous n'attendez pas dans l'entrée, par exemple top_sekrit .

Dans ce cas, nous pouvons :

s/HELLO/top_sekrit/     #will only replace the very first occurrence
s/.*top_sekrit//        #kill everything till end of the first HELLO

Bien sûr, avec une entrée plus simple, vous pourriez utiliser un mot plus petit, ou peut-être même un seul caractère.

HTH !