Divise une chaîne de caractères en un tableau de chaînes de caractères basé sur un délimiteur.

Question

J'essaie de trouver une fonction Delphi qui divise une chaîne d'entrée en un tableau de chaînes de caractères en fonction d'un délimiteur. J'en ai trouvé beaucoup en cherchant sur le web, mais toutes semblent avoir leurs propres problèmes et je n'ai pas réussi à en faire fonctionner une seule.

J'ai juste besoin de diviser une chaîne de caractères comme : "word:doc,txt,docx" dans un tableau basé sur ':'. Le résultat serait ['word', 'doc,txt,docx'] . Comment puis-je le faire ?

Answer 1

Vous pouvez utiliser la propriété TStrings.DelimitedText pour diviser une chaîne de caractères.

consultez cet échantillon

program Project28;

{$APPTYPE CONSOLE}

uses
  Classes,
  SysUtils;

procedure Split(Delimiter: Char; Str: string; ListOfStrings: TStrings) ;
begin
   ListOfStrings.Clear;
   ListOfStrings.Delimiter       := Delimiter;
   ListOfStrings.StrictDelimiter := True; // Requires D2006 or newer.
   ListOfStrings.DelimitedText   := Str;
end;

var
   OutPutList: TStringList;
begin
   OutPutList := TStringList.Create;
   try
     Split(':', 'word:doc,txt,docx', OutPutList) ;
     Writeln(OutPutList.Text);
     Readln;
   finally
     OutPutList.Free;
   end;
end.

UPDATE

Voir ceci lien pour une explication de StrictDelimiter .

Answer 2

Il n'est pas nécessaire de concevoir un Split fonction. Elle existe déjà, voyez : Classes.ExtractStrings .

Utilisez-le de la manière suivante :

program Project1;

{$APPTYPE CONSOLE}

uses
  Classes;

var
  List: TStrings;
begin
  List := TStringList.Create;
  try
    ExtractStrings([':'], [], PChar('word:doc,txt,docx'), List);
    WriteLn(List.Text);
    ReadLn;
  finally
    List.Free;
  end;
end.

Et pour répondre pleinement à la question ; List représente le tableau souhaité avec les éléments :

List[0] = 'word'
List[1] = 'doc,txt,docx'

Answer 3

Vous pouvez utiliser StrUtils.SplitString .

function SplitString(const S, Delimiters: string): TStringDynArray;

Sa description à partir du documentation :

Scinde une chaîne de caractères en différentes parties délimitées par les caractères de délimitation spécifiés.

Chaînes de fractionnement divise une chaîne de caractères en différentes parties délimitées par les caractères de délimitation spécifiés. S est la chaîne de caractères à diviser. Délimiteurs est une chaîne de caractères contenant les caractères définis comme délimiteurs.

Chaînes de fractionnement renvoie un tableau de chaînes de caractères de type System.Types.TStringDynArray qui contient les parties divisées de la chaîne originale.

Answer 4

J'utilise toujours quelque chose de similaire à ceci :

Uses
   StrUtils, Classes;

Var
  Str, Delimiter : String;
begin
  // Str is the input string, Delimiter is the delimiter
  With TStringList.Create Do
  try
    Text := ReplaceText(S,Delim,#13#10);

    // From here on and until "finally", your desired result strings are
    // in strings[0].. strings[Count-1)

  finally
    Free; //Clean everything up, and liberate your memory ;-)
  end;

end;

Answer 5

Semblable à la Explode() La fonction proposée par Mef, mais avec quelques différences (dont une que je considère comme une correction de bug) :

  type
    TArrayOfString = array of String;

  function SplitString(const aSeparator, aString: String; aMax: Integer = 0): TArrayOfString;
  var
    i, strt, cnt: Integer;
    sepLen: Integer;

    procedure AddString(aEnd: Integer = -1);
    var
      endPos: Integer;
    begin
      if (aEnd = -1) then
        endPos := i
      else
        endPos := aEnd + 1;

      if (strt < endPos) then
        result[cnt] := Copy(aString, strt, endPos - strt)
      else
        result[cnt] := '';

      Inc(cnt);
    end;

  begin
    if (aString = '') or (aMax < 0) then
    begin
      SetLength(result, 0);
      EXIT;
    end;

    if (aSeparator = '') then
    begin
      SetLength(result, 1);
      result[0] := aString;
      EXIT;
    end;

    sepLen := Length(aSeparator);
    SetLength(result, (Length(aString) div sepLen) + 1);

    i     := 1;
    strt  := i;
    cnt   := 0;
    while (i <= (Length(aString)- sepLen + 1)) do
    begin
      if (aString[i] = aSeparator[1]) then
        if (Copy(aString, i, sepLen) = aSeparator) then
        begin
          AddString;

          if (cnt = aMax) then
          begin
            SetLength(result, cnt);
            EXIT;
          end;

          Inc(i, sepLen - 1);
          strt := i + 1;
        end;

      Inc(i);
    end;

    AddString(Length(aString));

    SetLength(result, cnt);
  end;

Différences :

1. un paramètreMax limite le nombre de chaînes de caractères à renvoyer
2. Si la chaîne d'entrée est terminée par un séparateur, on considère qu'il existe une chaîne finale nominale "vide".

Exemples :

SplitString(':', 'abc') returns      :    result[0]  = abc

SplitString(':', 'a:b:c:') returns   :    result[0]  = a
                                          result[1]  = b
                                          result[2]  = c
                                          result[3]  = <empty string>

SplitString(':', 'a:b:c:', 2) returns:    result[0]  = a
                                          result[1]  = b

C'est le séparateur de fin de ligne et l'"élément final vide" théorique que je considère comme la correction du bug.

J'ai également incorporé le changement d'allocation de mémoire que j'ai suggéré, avec un raffinement (j'ai suggéré par erreur que la chaîne d'entrée pouvait contenir au maximum 50% de séparateurs, mais il est concevable qu'elle puisse bien sûr consister en 100% de chaînes de séparateurs, ce qui donne un tableau d'éléments vides !)