Comment copier une structure de répertoire mais n'inclure que certains fichiers (en utilisant les fichiers batch de Windows)

Question

Comme le titre l'indique, comment puis-je copier de manière récursive une structure de répertoire mais en n'incluant que certains fichiers. Par exemple, avec la structure de répertoire suivante :

folder1
  folder2
    folder3
      data.zip
      info.txt
      abc.xyz
    folder4
    folder5
      data.zip
      somefile.exe
      someotherfile.dll

Les dossiers data.zip et info.txt peuvent apparaître partout dans la structure du répertoire. Comment puis-je copier la structure complète du répertoire, mais n'inclure que les fichiers nommés data.zip et info.txt (tous les autres fichiers doivent être ignorés) ?

La structure du répertoire résultant devrait ressembler à ceci :

copy_of_folder1
  folder2
    folder3
      data.zip
      info.txt
    folder4
    folder5
      data.zip

Answer 1

Vous ne mentionnez pas s'il doit s'agir uniquement d'un lot, mais si vous pouvez utiliser ROBOCOPY essayez ceci :

ROBOCOPY C:\Source C:\Destination data.zip info.txt /E

EDIT : Changement du /S pour /E pour inclure les dossiers vides.

Answer 2

Une solution alternative qui copie un fichier à la fois et ne nécessite pas ROBOCOPY :

@echo off
setlocal enabledelayedexpansion

set "SOURCE_DIR=C:\Source"
set "DEST_DIR=C:\Destination"
set FILENAMES_TO_COPY=data.zip info.txt

for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
    if exist "%%F" (
        set FILE_DIR=%%~dpF
        set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
        xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
    )
)

L'instruction for externe génère toutes les combinaisons de chemins possibles du sous-répertoire dans SOURCE_DIR et le nom dans FILENAMES_TO_COPY . Pour chaque fichier existant, xcopy est invoqué. FILE_INTERMEDIATE_DIR contient le chemin du sous-répertoire du fichier au sein de SOURCE_DIR qui doit être créé dans DEST_DIR .

Answer 3

Essayez de passer la sortie de find (c'est à dire le chemin du fichier) dans cpio

find . -type f -name '*.jpg' | cpio -p -d -v targetdir/

cpio vérifie l'horodatage des fichiers cibles -- donc c'est sûr et rapide.

supprimez -v pour une opération plus rapide, une fois que vous vous y serez habitué.

Answer 4

Merci aux réponses précédentes. :)

Ce script nommé "r4k4copy.cmd" :

@echo off
for %%p in (SOURCE_DIR DEST_DIR FILENAMES_TO_COPY) do set %%p=
cls
echo :: Copy Files Including Folder Tree
echo :: http://stackoverflow.com
rem     /questions/472692/how-to-copy
rem     -a-directory-structure-but-only
rem     -include-certain-files-using-windows
echo :: ReScripted by r4k4
echo.
if "%1"=="" goto :NoParam
if "%2"=="" goto :NoParam
if "%3"=="" goto :NoParam
setlocal enabledelayedexpansion
set SOURCE_DIR=%1
set DEST_DIR=%2
set FILENAMES_TO_COPY=%3
for /R "%SOURCE_DIR%" %%F IN (%FILENAMES_TO_COPY%) do (
if exist "%%F" (
set FILE_DIR=%%~dpF
set FILE_INTERMEDIATE_DIR=!FILE_DIR:%SOURCE_DIR%=!
xcopy /E /I /Y "%%F" "%DEST_DIR%!FILE_INTERMEDIATE_DIR!"
)
)
goto :eof
:NoParam
echo.
echo Syntax: %0 [Source_DIR] [Dest_DIR] [FileName]
echo Eg.   : %0 D:\Root E:\Root\Lev1\Lev2\Lev3 *.JPG
echo Means : Copy *.JPG from D:\Root to E:\Root\Lev1\Lev2\Lev3

Il accepte les variables "Source", "Destination", et "Nom de fichier". Il peut également copier uniquement le type de fichiers spécifié ou certains noms de fichiers.

Toute amélioration est la bienvenue. :)

Answer 5

Similaire à la solution de Paulius, mais les fichiers dont vous ne vous souciez pas ne sont pas copiés puis supprimés :

@echo OFF

:: Replace c:\temp with the directory where folder1 resides.
cd c:\temp

:: You can make this more generic by passing in args for the source and destination folders.
for /f "usebackq" %%I in (`dir /b /s /a:-d folder1`) do @echo %%~nxI | find /V "data.zip" | find /v "info.txt" >> exclude_list.txt
xcopy folder1 copy_of_folder1 /EXCLUDE:exclude_list.txt /E /I