Ouvrir un fichier à la ligne avec la syntaxe "filename:line".

Question

Très souvent, les erreurs de compilation sont affichées avec l'icône file:line la syntaxe.

Ce serait bien de pouvoir copier-coller directement pour ouvrir le fichier à la bonne ligne.

Emacs dispose déjà d'un mode pour gérer cela dans les tampons (mode compilation, je crois), mais j'aimerais que cela soit disponible à partir de la ligne de commande du shell, puisque j'utilise le shell standard la plupart du temps en dehors d'Emacs.

Une idée sur la façon de modifier emacs pour apprendre file:line syntaxe pour ouvrir file à la ligne line ? (évidemment, si file:line existe réellement sur le disque, il doit être ouvert de préférence)

Answer 1

Vous pouvez le faire en utilisant emacsclient. Par exemple, pour ouvrir FILE à la ligne 4, colonne 3 dans un nouveau cadre :

emacsclient +4:3 FILE

Laissez tomber le :3 pour ouvrir simplement le fichier à la ligne 4.

Answer 2

J'ai les éléments suivants dans mon .emacs mais je ne l'ai pas trouvé aussi utile que je le pensais.

;; Open files and goto lines like we see from g++ etc. i.e. file:line#
;; (to-do "make `find-file-line-number' work for emacsclient as well")
;; (to-do "make `find-file-line-number' check if the file exists")
(defadvice find-file (around find-file-line-number
                             (filename &optional wildcards)
                             activate)
  "Turn files like file.cpp:14 into file.cpp and going to the 14-th line."
  (save-match-data
    (let* ((matched (string-match "^\\(.*\\):\\([0-9]+\\):?$" filename))
           (line-number (and matched
                             (match-string 2 filename)
                             (string-to-number (match-string 2 filename))))
           (filename (if matched (match-string 1 filename) filename)))
      ad-do-it
      (when line-number
        ;; goto-line is for interactive use
        (goto-char (point-min))
        (forward-line (1- line-number))))))

Answer 3

Et voici mon essai. Appelle l'original find-file-at-point

(defun find-file-at-point-with-line()
  "if file has an attached line num goto that line, ie boom.rb:12"
  (interactive)
  (setq line-num 0)
  (save-excursion
    (search-forward-regexp "[^ ]:" (point-max) t)
    (if (looking-at "[0-9]+")
         (setq line-num (string-to-number (buffer-substring (match-beginning 0) (match-end 0))))))
  (find-file-at-point)
  (if (not (equal line-num 0))
      (goto-line line-num)))

Answer 4

Vous pouvez utiliser un script bash :

#! /bin/bash
file=$(awk '{sub(/:[0-9]*$/,"")}1' <<< "$1")
line=$(awk '{sub(/^.*:/,"")}1' <<< "$1")
emacs --no-splash "+$line" "$file" &

Si vous appelez ce script pour openline et vous obtenez un message d'erreur, par ex.

Error: file.cpp:1046

vous pouvez faire

openline file.cpp:1046

pour ouvrir le file.cpp sur Emacs à la ligne 1046..

Answer 5

Une autre version du conseil sympa d'Ivan Andrus sur les fichiers de recherche qui fait à la fois la ligne + le numéro de colonne optionnel, comme vous le voyez dans les erreurs de node et coffeescript :

;; Open files and go places like we see from error messages, i e: path:line:col
;; (to-do "make `find-file-line-number' work for emacsclient as well")
;; (to-do "make `find-file-line-number' check if the file exists")
(defadvice find-file (around find-file-line-number
                             (path &optional wildcards)
                             activate)
  "Turn files like file.js:14:10 into file.js and going to line 14, col 10."
  (save-match-data
    (let* ((match (string-match "^\\(.*?\\):\\([0-9]+\\):?\\([0-9]*\\)$" path))
           (line-no (and match
                         (match-string 2 path)
                         (string-to-number (match-string 2 path))))
           (col-no (and match
                        (match-string 3 path)
                        (string-to-number (match-string 3 path))))
           (path (if match (match-string 1 path) path)))
      ad-do-it
      (when line-no
        ;; goto-line is for interactive use
        (goto-char (point-min))
        (forward-line (1- line-no))
        (when (> col-no 0)
          (forward-char (1- col-no)))))))