Techniques de programmation simples / astuces en Mathematica pour réaliser des graphiques pour le livre de mathématiques ?

Question

J'ai essayé de l'utiliser. Et c'est vraiment bien pour certains tracés, mais quand il s'agit de faire par exemple un triangle, je l'ai trouvé assez compliqué. J'ai compris comment dessiner un triangle mais comment ajouter ces marques d'angle, ces lignes courbes ?

Et comme je suis un débutant dans ce métier, l'écriture d'un livre, quelqu'un peut-il me recommander la meilleure façon de réaliser des graphiques de bonne qualité, par exemple comme dans l'image ci-dessous. Quels sont les meilleurs programmes à utiliser.

Merci pour toute suggestion et recommandation.

Answer 1

Voici une façon simple/basique de faire la première :

Graphics[{

 (* The dashed circle segment *)
 {
  Dashing[{.04, .01}], 
  Darker[Orange], 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {1, 2 \[Pi]}]
 },

 (* The solid circle segment *)
 {
  Orange, 
  AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {0, 1}]
 },

 (* The radial lines and the small circle segment *)
 Line[{{0, 0}, {1, 0}}],
 Line[{{0, 0}, {Cos[1], Sin[1]}}],
 Circle[{0, 0}, .2, {0, 1}],

 (* Various text labels *)
 {
  Text[Style["\[Theta]", 24], .3 {Cos[.5], Sin[.5]}], 
  Text[Style["s", 24], 1.1 {Cos[.5], Sin[.5]}], 
  Text[Style["r", 24], {.5, -.1}]
 }
}]

Ce qui suit est exactement la même chose, mais emballé dans Manipulate et paramétrée sur l'angle alpha :

Manipulate[
 Graphics[{
  {Dashing[{.04, .01}], Darker[Orange], AbsoluteThickness[2], 
  Circle[{0, 0}, 1, {\[Alpha], 2 \[Pi]}]},
  {Orange, AbsoluteThickness[2], Circle[{0, 0}, 1, {0, \[Alpha]}]},
  Line[{{0, 0}, {1, 0}}],
  Line[{{0, 0}, {Cos[\[Alpha]], Sin[\[Alpha]]}}],
  Circle[{0, 0}, .2, {0, \[Alpha]}],
  {Text[Style["\[Theta]", 
  24], .3 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["s", 24], 1.1 {Cos[\[Alpha]/2], Sin[\[Alpha]/2]}], 
  Text[Style["r", 24], {.5, -.1}]}
 }],
{{\[Alpha], 1}, 0, 2 \[Pi]}]

Si vous déplacez le curseur, le contenu change en conséquence :

Answer 2

Editar Vous pouvez également vous inspirer du projet Démonstrations. Ce sont les démonstrations liées au triangle. Après avoir jeté un coup d'œil rapide, je pense que vous devriez voir les démonstrations liées à la géométrie en Jay Warendorff . Il en a fait beaucoup, et ils utilisent un ensemble structuré de fonctions liées à la géométrie que vous pouvez très probablement réutiliser.

---

Voici un angleArc pour vous aider à démarrer. Il ne s'agit que d'un petit exemple de fonction d'aide que vous pourriez utiliser, il y a beaucoup de possibilités d'amélioration.

angleArc[Polygon[vertices_List, ___], r_, i_] :=
 Module[{a, b, c, phi1, phi2},
  {a, b, c} = Take[RotateLeft[vertices, i-2], 3];
  {phi1, phi2} = Sort@N[{ArcTan @@ (a - b), ArcTan @@ (c - b)}];
  If[phi2 - phi1 > Pi, phi1 += 2 Pi];
  Circle[b, r, {phi2, phi1}]
 ]

poly = Polygon[{{0, 0}, {1, 2}, {2, 1}}];

Graphics[{EdgeForm[Thick], FaceForm[None], poly, 
  Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]}]

Manipulate[
 With[{poly = Polygon[{a, b, c}]},
  Graphics[
   {EdgeForm[Thick], FaceForm[None], poly, 
    Table[angleArc[poly, .2, i], {i, Length[poly[[1]]]}]},
   PlotRange -> 2 {{-1, 1}, {-1, 1}}, Frame -> True
   ]
  ],
 {{a, {0, 0}}, Locator}, {{b, {1, 0}}, Locator}, {{c, {0, 1}}, Locator}
 ]

Answer 3

Un excellent produit, soutenu par Wolfram, est le suivant Geometrica . Ce n'est pas un complément bon marché à 495 $, mais il produira des diagrammes comme le vôtre beaucoup plus facilement que s'il était fait en mode brut. MMA Mathematica. Il s'agit essentiellement d'une très grande extension de l'approche de Szabolcs dans les commentaires - une bibliothèque de fonctions pour dessiner des choses.

Answer 4

J'aime beaucoup Mathematica. Mais il existe de meilleures options pour le dessin géométrique.

Ici vous avez un croquis de cinq minutes réalisé avec Expressions géométriques (très basse résolution utilisée) :

Geometry Expressions effectue de beaux calculs de géométrie planaire et peut exporter les résultats vers Mma en ligne.

Answer 5

Oui, les outils graphiques intégrés de Mathematica sont un peu bizarres par endroits, et il y a quelques omissions gênantes. Mais il y a une bonne gamme de graphiques de base et, en plus, vous n'êtes qu'à quelques touches des outils mathématiques dont vous avez besoin pour corriger certaines des déficiences de l'éditeur graphique. Vous avez besoin d'un arc ? Il suffit de le calculer ci-dessous et de le copier/coller. Impossible de faire ça avec Adobe Illustrator ! L'accès aux équations et aux caractères grecs est également très large. Cela peut être utile quand on n'a rien d'autre sous la main.

Voici la première - elle n'est pas totalement inacceptable ... :)