Compter les occurrences d'un caractère spécifique dans une chaîne de caractères

Question

Quelle est la manière la plus simple de compter le nombre d'occurrences d'un caractère spécifique dans une chaîne de caractères ?

En d'autres termes, je dois écrire une fonction, countTheCharacters(), de manière à ce que

str = "the little red hen"
count = countTheCharacters(str,"e") ' Count should equal 4
count = countTheCharacters(str,"t") ' Count should equal 3

Answer 1

La méthode la plus simple consiste à parcourir en boucle les caractères de la chaîne :

Public Function CountCharacter(ByVal value As String, ByVal ch As Char) As Integer
  Dim cnt As Integer = 0
  For Each c As Char In value
    If c = ch Then 
      cnt += 1
    End If
  Next
  Return cnt
End Function

Utilisation :

count = CountCharacter(str, "e"C)

Une autre approche, presque aussi efficace et qui permet d'obtenir un code plus court, consiste à utiliser les méthodes d'extension LINQ :

Public Function CountCharacter(ByVal value As String, ByVal ch As Char) As Integer
  Return value.Count(Function(c As Char) c = ch)
End Function

Answer 2

C'est la méthode la plus simple :

text = "the little red hen"
count = text.Split("e").Length -1 ' Equals 4
count = text.Split("t").Length -1 ' Equals 3

Answer 3

Vous pouvez essayer ceci

Dim occurCount As Integer = Len(testStr) - Len(testStr.Replace(testCharStr, ""))

Answer 4

Voici une version simple.

text.count(function(x) x = "a")

Ce qui précède vous donne le nombre de "a" dans la chaîne de caractères. Si vous voulez ignorer la casse :

text.count(function(x) Ucase(x) = "A")

Ou si vous voulez simplement compter les lettres :

text.count(function(x) Char.IsLetter(x) = True)

Tentez votre chance !

Answer 5

Ou (en VB.NET) :

Function InstanceCount(ByVal StringToSearch As String,
                       ByVal StringToFind As String) As Long
    If Len(StringToFind) Then
        InstanceCount = UBound(Split(StringToSearch, StringToFind))
    End If
End Function