Sélection d'un répertoire avec TOpenDialog

Question

J'aimerais vraiment connaître les différentes façons de sélectionner un répertoire avec le TOpenDialog, que ce soit en téléchargeant un nouveau composant ou en utilisant ce qui est fourni par Delphi, mais de préférence en utilisant ce qui est fourni par Delphi.

Auparavant, j'utilisais la commande SelectDirectory, mais je pense que les utilisateurs de mon programme auraient des difficultés à rechercher le répertoire spécifié.

Je pense que le SelectDirectory est "faible" parce que cela peut être un long processus de recherche du répertoire que vous voulez. Disons, par exemple, que vous voulez naviguer vers le répertoire Application Data. Combien de temps ou de difficultés faut-il pour y accéder ? En fin de compte, les utilisateurs peuvent même ne pas atteindre le répertoire souhaité.

J'ai besoin de quelque chose comme ça où l'utilisateur peut copier et coller des répertoires dans la barre d'adresse du répertoire en haut de la page.

Merci pour toutes vos réponses.

Answer 1

Vous pouvez utiliser le TFileOpenDialog (sur Vista+) :

with TFileOpenDialog.Create(nil) do
  try
    Options := [fdoPickFolders];
    if Execute then
      ShowMessage(FileName);
  finally
    Free;
  end;

Personnellement, j'utilise toujours le TFileOpenDialog sur Vista+ et le repli en utilisant le SelectDirectory (le bon !) sur XP, comme ceci :

if Win32MajorVersion >= 6 then
  with TFileOpenDialog.Create(nil) do
    try
      Title := 'Select Directory';
      Options := [fdoPickFolders, fdoPathMustExist, fdoForceFileSystem]; // YMMV
      OkButtonLabel := 'Select';
      DefaultFolder := FDir;
      FileName := FDir;
      if Execute then
        ShowMessage(FileName);
    finally
      Free;
    end
else
  if SelectDirectory('Select Directory', ExtractFileDrive(FDir), FDir,
             [sdNewUI, sdNewFolder]) then
    ShowMessage(FDir)

Answer 2

Vous savez que les deux fonctions surchargées appelées FileCtrl.SelectDirectory produisent des dialogues totalement différents, non ?

SelectDirectory(s, [], 0);

SelectDirectory('Select a directory', s, s, []);

Answer 3

Il suffit d'inclure

FileCtrl.pas

var
  sDir:String;
begin
  SelectDirectory('Your caption','',sDir);
end;

Laissez le deuxième argument vide si vous voulez voir tous les répertoires, y compris le bureau. Si vous définissez le deuxième argument comme un chemin d'accès valide, votre boîte de dialogue affichera ce chemin d'accès au dossier supérieur et vous ne pourrez pas naviguer au-delà.

Par exemple :

SelectDirectory('Your caption','C:\',sDir) ne vous laissera pas sélectionner autre chose que C:\ comme D:\ ou E:\ etc.

Il est donc bon de le laisser vide.

Answer 4

Je viens de trouver le code ci-dessous qui semble fonctionner correctement sous XP et Vista, Win7. Il fournit une interface utilisateur permettant à un utilisateur de sélectionner un répertoire. Il utilise TOpenDialog, mais lui envoie quelques messages pour nettoyer l'apparence dans le but de sélectionner un répertoire.

Après avoir souffert des capacités limitées offertes par Windows lui-même, c'est un plaisir de pouvoir offrir à mes utilisateurs une interface utilisateur familière où ils peuvent parcourir et sélectionner une liste de produits. dossier confortablement.

Cela faisait longtemps que je cherchais quelque chose comme ça, alors j'ai pensé le poster ici pour que d'autres puissent en profiter.

Voici à quoi cela ressemble dans Win 7 :

//***********************
//** Choose a directory **
//**   uses Messages   **
//***********************
  //General usage here:
  //  http://www.delphipages.com/forum/showthread.php?p=185734
  //Need a class to hold a procedure to be called by Dialog.OnShow:
  type TOpenDir = class(TObject)
  public
    Dialog: TOpenDialog;
    procedure HideControls(Sender: TObject);
  end;
  //This procedure hides de combo box of file types...
  procedure TOpenDir.HideControls(Sender: TObject);
  const
    //CDM_HIDECONTROL and CDM_SETCONTROLTEXT values from:
    //  doc.ddart.net/msdn/header/include/commdlg.h.html
    //  CMD_HIDECONTROL = CMD_FIRST + 5 = (WM_USER + 100) + 5;
    //Usage of CDM_HIDECONTROL and CDM_SETCONTROLTEXT here:
    //  msdn.microsoft.com/en-us/library/ms646853%28VS.85%29.aspx
    //  msdn.microsoft.com/en-us/library/ms646855%28VS.85%29.aspx
    CDM_HIDECONTROL =    WM_USER + 100 + 5;
    CDM_SETCONTROLTEXT = WM_USER + 100 + 4;
    //Component IDs from:
    //  msdn.microsoft.com/en-us/library/ms646960%28VS.85%29.aspx#_win32_Open_and_Save_As_Dialog_Box_Customization
    //Translation into exadecimal in dlgs.h:
    //  www.koders.com/c/fidCD2C946367FEE401460B8A91A3DB62F7D9CE3244.aspx
    //
    //File type filter...
    cmb1: integer  = $470; //Combo box with list of file type filters
    stc2: integer  = $441; //Label of the file type
    //File name const...
    cmb13: integer = $47c; //Combo box with name of the current file
    edt1: integer  = $480; //Edit with the name of the current file
    stc3: integer  = $442; //Label of the file name combo
  var H: THandle;
  begin
    H:= GetParent(Dialog.Handle);
    //Hide file types combo...
    SendMessage(H, CDM_HIDECONTROL, cmb1,  0);
    SendMessage(H, CDM_HIDECONTROL, stc2,  0);
    //Hide file name label, edit and combo...
    SendMessage(H, CDM_HIDECONTROL, cmb13, 0);
    SendMessage(H, CDM_HIDECONTROL, edt1,  0);
    SendMessage(H, CDM_HIDECONTROL, stc3,  0);
    //NOTE: How to change label text (the lentgh is not auto):
    //SendMessage(H, CDM_SETCONTROLTEXT, stc3, DWORD(pChar('Hello!')));
  end;
//Call it when you need the user to chose a folder for you...
function GimmeDir(var Dir: string): boolean;
var
  OpenDialog: TOpenDialog;
  OpenDir: TOpenDir;
begin
  //The standard dialog...
  OpenDialog:= TOpenDialog.Create(nil);
  //Objetc that holds the OnShow code to hide controls
  OpenDir:= TOpenDir.create;
  try
    //Conect both components...
    OpenDir.Dialog:= OpenDialog;
    OpenDialog.OnShow:= OpenDir.HideControls;
    //Configure it so only folders are shown (and file without extension!)...
    OpenDialog.FileName:= '*.';
    OpenDialog.Filter:=   '*.';
    OpenDialog.Title:=    'Chose a folder';
    //No need to check file existis!
    OpenDialog.Options:= OpenDialog.Options + [ofNoValidate];
    //Initial folder...
    OpenDialog.InitialDir:= Dir;
    //Ask user...
    if OpenDialog.Execute then begin
      Dir:= ExtractFilePath(OpenDialog.FileName);
      result:= true;
    end else begin
      result:= false;
    end;
  finally
    //Clean up...
    OpenDir.Free;
    OpenDialog.Free;
  end;
end;

Answer 5

Si vous utilisez JVCL vous pouvez utiliser TJvSelectDirectory. Avec cette fonction, vous pouvez passer de l'ancien au nouveau style en définissant une propriété. Par exemple :

Dlg := TJvSelectDirectory.Create(Self);
try
    Dlg.Title := MyTitle;
    Dlg.InitialDir := MyStartDir;
    Dlg.Options := Dlg.Options + [sdAllowCreate, sdPerformCreate];     
    Dlg.ClassicDialog := False;   //switch style
    if Dlg.Execute() then
      NewDir := Dlg.Directory;
finally
    Dlg.Free;
end;