Sélectionnez un fichier ou un dossier dans la même boîte de dialogue en .NET.

Question

Existe-t-il un moyen "simple" de sélectionner un fichier OU un dossier dans la même boîte de dialogue ?

Dans de nombreuses applications que je crée, j'autorise la saisie de fichiers ou de dossiers. Jusqu'à présent, j'ai toujours fini par créer un commutateur permettant de basculer entre les boîtes de dialogue de sélection de fichiers ou de dossiers, ou par m'en tenir à la seule fonctionnalité de glisser-déposer.

Puisque cela semble si élémentaire, j'imagine que cela a déjà été créé auparavant, mais une recherche sur Google ne donne pas beaucoup d'informations. Il semblerait donc que je doive repartir de zéro et créer un dialogue de sélection personnalisé, mais je préfère ne pas introduire de problèmes en réinventant la roue pour une tâche aussi triviale.

Quelqu'un a-t-il des conseils ou des solutions existantes ?

Pour que l'interface utilisateur reste cohérente, il serait bon qu'il soit possible d'étendre le OpenFileDialog (ou le FolderBrowserDialog).

Answer 1

Techniquement, c'est possible. Le dialogue shell utilisé par FolderBrowseDialog a la capacité de retourner à la fois les fichiers et les dossiers. Malheureusement, cette capacité n'est pas exposée dans .NET. Même la réflexion ne permet pas d'activer le drapeau d'option requis.

Pour que cela fonctionne, vous devez P/Invoke SHBrowseForFolder() avec l'indicateur BIF_BROWSEINCLUDEFILES activé dans BROWSEINFO.ulFlags (valeur = 0x4000). Le P/Invoke est granuleux, il est préférable de copier et coller le code à partir de une autre source ou la classe FolderBrowseDialog elle-même avec l'aide de Reflector.

Answer 2

En me basant sur les conseils ci-dessus, j'ai trouvé un code fonctionnel qui utilise la boîte de dialogue standard Folder Browser à l'endroit suivant : http://topic.csdn.net/t/20020703/05/845468.html

La classe pour la boîte de dialogue étendue du navigateur de dossiers

Imports System   
Imports System.Text   
Imports System.Windows.Forms   
Imports System.Runtime.InteropServices   

Public Class DirectoryDialog 
    Public Structure BROWSEINFO 
        Public hWndOwner As IntPtr 
        Public pIDLRoot As Integer 
        Public pszDisplayName As String 
        Public lpszTitle As String 
        Public ulFlags As Integer 
        Public lpfnCallback As Integer 
        Public lParam As Integer 
        Public iImage As Integer 
    End Structure 

    Const MAX_PATH As Integer = 260

    Public Enum BrowseForTypes As Integer 
        Computers = 4096 
        Directories = 1 
        FilesAndDirectories = 16384 
        FileSystemAncestors = 8 
    End Enum 

    Declare Function CoTaskMemFree Lib "ole32" Alias "CoTaskMemFree" (ByVal hMem As IntPtr) As Integer 
    Declare Function lstrcat Lib "kernel32" Alias "lstrcat" (ByVal lpString1 As String, ByVal lpString2 As String) As IntPtr 
    Declare Function SHBrowseForFolder Lib "shell32" Alias "SHBrowseForFolder" (ByRef lpbi As BROWSEINFO) As IntPtr 
    Declare Function SHGetPathFromIDList Lib "shell32" Alias "SHGetPathFromIDList" (ByVal pidList As IntPtr, ByVal lpBuffer As StringBuilder) As Integer 
    Protected Function RunDialog(ByVal hWndOwner As IntPtr) As Boolean 

        Dim udtBI As BROWSEINFO = New BROWSEINFO() 
        Dim lpIDList As IntPtr 
        Dim hTitle As GCHandle = GCHandle.Alloc(Title, GCHandleType.Pinned) 
        udtBI.hWndOwner = hWndOwner 
        udtBI.lpszTitle = Title 
        udtBI.ulFlags = BrowseFor 
        Dim buffer As StringBuilder = New StringBuilder(MAX_PATH) 
        buffer.Length = MAX_PATH 
        udtBI.pszDisplayName = buffer.ToString() 
        lpIDList = SHBrowseForFolder(udtBI) 
        hTitle.Free() 
        If lpIDList.ToInt64() <> 0 Then 
            If BrowseFor = BrowseForTypes.Computers Then 
                m_Selected = udtBI.pszDisplayName.Trim() 
            Else 
                Dim path As StringBuilder = New StringBuilder(MAX_PATH) 
                SHGetPathFromIDList(lpIDList, path) 
                m_Selected = path.ToString() 
            End If 
            CoTaskMemFree(lpIDList) 
        Else 
            Return False 
        End If 
        Return True 
    End Function 

    Public Function ShowDialog() As DialogResult 
        Return ShowDialog(Nothing) 
    End Function 

    Public Function ShowDialog(ByVal owner As IWin32Window) As DialogResult 
        Dim handle As IntPtr 
        If Not owner Is Nothing Then 
            handle = owner.Handle 
        Else 
            handle = IntPtr.Zero 
        End If 
        If RunDialog(handle) Then 
            Return DialogResult.OK 
        Else 
            Return DialogResult.Cancel 
        End If 
    End Function 

    Public Property Title() As String 
        Get 
            Return m_Title 
        End Get 
        Set(ByVal Value As String) 
            If Value Is DBNull.Value Then 
                Throw New ArgumentNullException() 
            End If 
            m_Title = Value 
        End Set 
    End Property

    Public ReadOnly Property Selected() As String 
        Get 
            Return m_Selected 
        End Get 
    End Property 

    Public Property BrowseFor() As BrowseForTypes
        Get 
            Return m_BrowseFor 
        End Get 
        Set(ByVal Value As BrowseForTypes) 
            m_BrowseFor = Value 
        End Set 
    End Property 

    Private m_BrowseFor As BrowseForTypes = BrowseForTypes.Directories 
    Private m_Title As String = "" 
    Private m_Selected As String = "" 

    Public Sub New() 
    End Sub
End Class 

Le code pour implémenter le dialogue étendu

Sub Button1Click(ByVal sender As Object, ByVal e As EventArgs)
    Dim frmd As DirectoryDialog = New DirectoryDialog()
    ' frmd.BrowseFor = DirectoryDialog.BrowseForTypes.Directories   
    ' frmd.BrowseFor = DirectoryDialog.BrowseForTypes.Computers   
    frmd.BrowseFor = DirectoryDialog.BrowseForTypes.FilesAndDirectories   
    frmd.Title = "Select a file or a folder"    
    If frmd.ShowDialog(Me) = DialogResult.OK Then   
        MsgBox(frmd.Selected)   
    End If   
End Sub

Answer 3

Cela a été fait. Vous pouvez utiliser FolderBrowserDialogEx - un dérivé réutilisable du FolderBrowserDialog intégré. Celui-ci vous permet de taper un chemin, même un chemin UNC. Vous pouvez rechercher des dossiers, ou des fichiers+dossiers. Vous pouvez rechercher des ordinateurs ou des imprimantes. Basé sur le FBD intégré, mais ... meilleur. Plus flexible. Si vous cliquez sur un dossier dans l'interface graphique, le chemin apparaît dans la zone de texte. Si vous entrez un chemin, le dossier est activé. Beaucoup d'options qui manquent à la boîte de dialogue intégrée.

Code source complet. Gratuit. Licence MS-Public.

Code pour l'utiliser :

     var dlg1 = new Ionic.Utils.FolderBrowserDialogEx();
     dlg1.Description = "Select a folder to extract to:";
     dlg1.ShowNewFolderButton = true;
     dlg1.ShowEditBox = true;
     //dlg1.NewStyle = false;
     dlg1.SelectedPath = txtExtractDirectory.Text;
     dlg1.ShowFullPathInEditBox = true;
     dlg1.RootFolder = System.Environment.SpecialFolder.MyComputer;

     // Show the FolderBrowserDialog.
     DialogResult result = dlg1.ShowDialog();
     if (result == DialogResult.OK)
     {
         txtExtractDirectory.Text = dlg1.SelectedPath;
     }

Answer 4

Vous pouvez utiliser l'OpenFileDialog standard pour sélectionner un dossier. Voici un article de CodeProject qui démontre une façon de le faire ( http://www.codeproject.com/KB/dialog/OpenFileOrFolderDialog.aspx ).

Answer 5

A ma connaissance, il n'y a rien dans le cadre .NET qui permette de faire cela.

Les boîtes de dialogue de fichiers .NET dérivent de CommonDialog :

Les classes héritées doivent d'implémenter RunDialog en invoquant ShowDialog pour créer une boîte de boîte de dialogue commune. Les classes héritées peuvent surcharger HookProc pour implémenter crochet de boîte de dialogue spécifique de la boîte de dialogue.