Exécuter une commande shell sans filtrage depuis Vim

Question

Je veux sélectionner un bloc de texte (par exemple, V% ) et utiliser le texte comme entrée d'une commande shell (par exemple, wc o pbcopy ) - mais je Ne le fais pas. Je ne veux pas modifier le tampon actuel - je veux juste voir la sortie de la commande (s'il y en a une) puis continuer l'édition sans aucune modification.

Dactylographie V%!wc se traduit par :'<,'>!wc et commute le bloc de texte pour la sortie de la fonction wc commandement.

Comment transmettre un morceau de texte à une commande shell arbitraire sans affecter le tampon actuel ?

Answer 1

Sélectionnez votre bloc de texte, puis tapez ces touches :w !sh

Le tout devrait ressembler à ça :

:'<,'>w !sh

C'est ça. Il ne m'a fallu que 8 ans pour l'apprendre : )

note : taper : après avoir sélectionné du texte produit :'<,'> une plage indiquant le début et la fin de la sélection.

Mise à jour 2016 : Il s'agit en réalité d'une seule utilisation du générique :

'<,'>w !cli_command

Ce qui vous permet essentiellement d'"envoyer" des parties arbitraires de votre fichier à des commandes externes et de voir les résultats dans une fenêtre vi temporaire sans altérer votre tampon. D'autres exemples utiles seraient :

'<,'>w !wc
'<,'>w !to_file my_file

Je trouve honnêtement qu'il est plus utile de modifier le tampon actuel. Cette variété est simplement :

'<,'>!wc
'<,'>!to_file my_file

Answer 2

Une possibilité serait d'utiliser system() dans une commande personnalisée, quelque chose comme ça :

command! -range -nargs=1 SendToCommand <line1>,<line2>call SendToCommand(<q-args>) 

function! SendToCommand(UserCommand) range
    " Get a list of lines containing the selected range
    let SelectedLines = getline(a:firstline,a:lastline)
    " Convert to a single string suitable for passing to the command
    let ScriptInput = join(SelectedLines, "\n") . "\n"
    " Run the command
    let result = system(a:UserCommand, ScriptInput)
    " Echo the result (could just do "echo system(....)")
    echo result
endfunction

Appelez cela avec (par exemple) :

:'<,'>SendToCommand wc -w

Notez que si vous appuyez sur V%: le :'<,'> sera saisie pour vous.

:help command
:help command-range
:help command-nargs
:help q-args
:help function
:help system()
:help function-range

Answer 3

Mise à jour : ma réponse est absurde.

La réponse de @pixelearth est bonne, mais j'avais un peu de mal à comprendre ce qu'il faisait exactement, alors j'ai écrit ce qui suit. Cette séquence de commandes vous permet d'exécuter wc -l sur votre sélection visuelle. wc -l compte simplement le nombre de lignes qui lui sont passées.

1. Dans Vim, passez en mode visuel en utilisant v
2. Sélectionnez quelques lignes en descendant : jjjj
3. Type : que Vim va traduire a :'<,'>
4. Type w !wc -l votre ligne de commande complète devrait maintenant être :'<,'>w !wc -l
5. Appuyez sur la touche Entrée pour obtenir le résultat de votre commande (dans cet exemple, il s'agit de 4).
6. Appuyez sur Enter pour poursuivre l'édition

Je ne comprends pas ce qui se passe exactement aux étapes 3 et 4, mais je sais que cela fonctionne.

Answer 4

Je sais que ce n'est pas la solution idéale, mais si tout le reste échoue, vous pouvez toujours simplement appuyer sur u après avoir exécuté la commande pour annuler le changement de tampon.