Tester ou vérifier si la feuille existe

Question

Dim wkbkdestination As Workbook
Dim destsheet As Worksheet

For Each ThisWorkSheet In wkbkorigin.Worksheets 
    'this throws subscript out of range if there is not a sheet in the destination 
    'workbook that has the same name as the current sheet in the origin workbook.
    Set destsheet = wkbkdestination.Worksheets(ThisWorkSheet.Name) 
Next

En gros, je passe en revue toutes les feuilles du classeur d'origine, puis j'active la fonction destsheet dans le classeur de destination vers la feuille portant le même nom que la feuille actuellement itérée dans le classeur d'origine.

Comment puis-je tester si cette feuille existe ? Quelque chose comme :

If wkbkdestination.Worksheets(ThisWorkSheet.Name) Then

Answer 1

Certaines personnes n'aiment pas cette approche en raison d'une utilisation "inappropriée" de la gestion des erreurs, mais je pense que c'est considéré comme acceptable en VBA... Une autre approche consiste à parcourir en boucle toutes les feuilles jusqu'à ce que vous trouviez une correspondance.

Function WorksheetExists(shtName As String, Optional wb As Workbook) As Boolean
    Dim sht As Worksheet

    If wb Is Nothing Then Set wb = ThisWorkbook
    On Error Resume Next
    Set sht = wb.Sheets(shtName)
    On Error GoTo 0
    WorksheetExists = Not sht Is Nothing
End Function

Answer 2

Si vous êtes spécifiquement intéressé par les feuilles de calcul uniquement, vous pouvez utiliser un simple appel Evaluate :

Function WorksheetExists(sName As String) As Boolean
    WorksheetExists = Evaluate("ISREF('" & sName & "'!A1)")
End Function

Answer 3

Vous n'avez pas besoin de gérer les erreurs pour y parvenir. Tout ce que vous avez à faire est d'itérer sur toutes les feuilles de calcul et de vérifier si le nom spécifié existe :

Dim exists As Boolean

For i = 1 To Worksheets.Count
    If Worksheets(i).Name = "MySheet" Then
        exists = True
    End If
Next i

If Not exists Then
    Worksheets.Add.Name = "MySheet"
End If

Answer 4

J'ai écrit celui-ci :

Function sheetExist(sSheet As String) As Boolean
On Error Resume Next
sheetExist = (ActiveWorkbook.Sheets(sSheet).Index > 0)
End Function

Answer 5

Comme la vérification des membres d'une collection est un problème général, voici une version abstraite de la réponse de Tim :

Function Contains(objCollection As Object, strName as String) As Boolean
    Dim o as Object
    On Error Resume Next
    set o = objCollection(strName)
    Contains = (Err.Number = 0)
    Err.Clear
 End Function

Cette fonction peut être utilisée avec n'importe quel objet de type collection ( Shapes , Range , Names , Workbooks etc.).

Pour vérifier l'existence d'une feuille, utilisez If Contains(Sheets, "SheetName") ...