Comment imprimer VARCHAR(MAX) à l'aide de l'instruction Print ?

Question

J'ai un code qui est :

DECLARE @Script VARCHAR(MAX)

SELECT @Script = definition FROM manged.sys.all_sql_modules sq
where sq.object_id = (SELECT object_id from managed.sys.objects 
Where type = 'P' and Name = 'usp_gen_data')

Declare @Pos int

SELECT  @pos=CHARINDEX(CHAR(13)+CHAR(10),@script,7500)

PRINT SUBSTRING(@Script,1,@Pos)

PRINT SUBSTRING(@script,@pos,8000)

La longueur du script est d'environ 10 000 caractères et comme j'utilise la déclaration d'impression qui ne peut contenir qu'un maximum de 8 000 caractères. J'utilise donc deux instructions print.

Le problème est que lorsque j'ai un script de 18000 caractères, j'avais l'habitude d'utiliser 3 instructions print.

Existe-t-il un moyen de définir le nombre d'instructions d'impression en fonction de la longueur du script ?

Answer 1

Je sais que c'est une vieille question, mais ce que j'ai fait n'est pas mentionné ici.

Pour moi, la procédure suivante a fonctionné (jusqu'à 16 000 caractères)

DECLARE @info NVARCHAR(MAX)

--SET @info to something big

PRINT CAST(@info AS NTEXT)

Si vous avez plus de 16k chars, vous pouvez combiner avec la réponse de @Yovav comme ceci (64k devrait être suffisant pour tout le monde ;)

    print cast( substring(@info, 1, 16000) as ntext )
    print cast( substring(@info, 16001, 32000) as ntext )
    print cast( substring(@info, 32001, 48000) as ntext )
    print cast( substring(@info, 48001, 64000) as ntext )

Answer 2

La solution suivante n'utilise pas l'option PRINT déclaration. Il fonctionne bien en combinaison avec le SQL Server Management Studio.

SELECT CAST('<root><![CDATA[' + @MyLongString + ']]></root>' AS XML)

Vous pouvez cliquer sur le fichier XML retourné pour le développer dans la visionneuse XML intégrée.

La taille affichée est assez généreusement limitée côté client. Pour cela, il faut se rendre sur le site Tools/Options/Query Results/SQL Server/Results to Grid/XML data pour l'ajuster si nécessaire.

Answer 3

Voici comment procéder :

DECLARE @String NVARCHAR(MAX);
DECLARE @CurrentEnd BIGINT; /* track the length of the next substring */
DECLARE @offset tinyint; /*tracks the amount of offset needed */
set @string = replace(  replace(@string, char(13) + char(10), char(10))   , char(13), char(10))

WHILE LEN(@String) > 1
BEGIN
    IF CHARINDEX(CHAR(10), @String) between 1 AND 4000
    BEGIN
           SET @CurrentEnd =  CHARINDEX(char(10), @String) -1
           set @offset = 2
    END
    ELSE
    BEGIN
           SET @CurrentEnd = 4000
            set @offset = 1
    END   
    PRINT SUBSTRING(@String, 1, @CurrentEnd) 
    set @string = SUBSTRING(@String, @CurrentEnd+@offset, LEN(@String))   
END /*End While loop*/

Tiré de http://ask.sqlservercentral.com/questions/3102/any-way-around-the-print-limit-of-nvarcharmax-in-s.html

Answer 4

Vous pourriez faire une WHILE en se basant sur le décompte de votre script divisé par 8000.

EG :

DECLARE @Counter INT
SET @Counter = 0
DECLARE @TotalPrints INT
SET @TotalPrints = (LEN(@script) / 8000) + 1
WHILE @Counter < @TotalPrints 
BEGIN
    -- Do your printing...
    SET @Counter = @Counter + 1
END

Answer 5

Je suis tombé sur cette question et je voulais quelque chose de plus simple... Essayez ce qui suit :

SELECT [processing-instruction(x)]=@Script FOR XML PATH(''),TYPE