Un fichier batch Windows peut-il déterminer son propre nom de fichier ?

Question

Un fichier batch Windows peut-il déterminer son propre nom de fichier ?

Par exemple, si je lance le fichier batch C:\Temp\myScript.bat Est-ce qu'il y a une commande dans myScript.bat qui peut déterminer la chaîne "myScript.bat" ?

Answer 1

Oui.

Utilisez la fonction spéciale %0 pour obtenir le chemin d'accès au fichier actuel.

Écrire à %~n0 pour obtenir juste le nom du fichier sans l'extension.

Écrire à %~n0%~x0 pour obtenir le nom du fichier et son extension.

Il est également possible d'écrire %~nx0 pour obtenir le nom du fichier et son extension.

Answer 2

Vous pouvez obtenir le nom du fichier, mais aussi le chemin complet, en fonction de ce que vous placez entre le '%~' et le '0'. Faites votre choix parmi

d -- drive
p -- path
n -- file name
x -- extension
f -- full path

Par exemple, de l'intérieur c : \tmp\foo.bat , %~nx0 vous donne "foo.bat", alors que %~dpnx0 donne "c" : \tmp\foo.bat ". Notez que les pièces sont toujours assemblées dans l'ordre canonique, donc si vous faites le malin et essayez de %~xnpd0 vous toujours obtenir "c : \tmp\foo.bat "

Answer 3

En utilisant le script suivant, basé sur la réponse de SLaks, j'ai déterminé que la bonne réponse est :

echo The name of this file is: %~n0%~x0
echo The name of this file is: %~nx0

Et voici mon test script :

@echo off
echo %0
echo %~0
echo %n0
echo %x0
echo %~n0
echo %dp0
echo %~dp0
pause

Ce que je trouve intéressant, c'est que %nx0 ne fonctionnera pas, étant donné que nous savons que le caractère '~' est généralement utilisé pour supprimer/réduire les guillemets d'une variable.

Answer 4

N'oubliez pas que 0 est un cas particulier de numéros de paramètres à l'intérieur d'un fichier batch, où 0 signifie ce fichier comme indiqué sur la ligne de commande .

Ainsi, si le fichier est monfichier.bat, vous pouvez l'appeler de plusieurs manières, comme suit, chacune d'entre elles vous donnant un résultat de différents sortie de la %0 o %~0 l'usage :

myfile

myfile.bat

mydir\myfile.bat

c:\mydir\myfile.bat

"c:\mydir\myfile.bat"

Tous les appels ci-dessus sont légaux si vous les appelez à partir de la place relative correcte du répertoire dans lequel ils existent. %~0 supprime les citations du dernier exemple, tandis que %0 ne le fait pas.

Parce qu'ils donnent tous des résultats différents, %0 et %~0 sont très peu susceptibles d'être ce que vous voulez réellement utiliser.

Voici un fichier batch pour illustrer :

@echo Full path and filename: %~f0
@echo Drive: %~d0
@echo Path: %~p0
@echo Drive and path: %~dp0
@echo Filename without extension: %~n0
@echo Filename with    extension: %~nx0
@echo Extension: %~x0
@echo Filename as given on command line: %0
@echo Filename as given on command line minus quotes: %~0
@REM Build from parts
@SETLOCAL
@SET drv=%~d0
@SET pth=%~p0
@SET fpath=%~dp0
@SET fname=%~n0
@SET ext=%~x0
@echo Simply Constructed name: %fpath%%fname%%ext%
@echo Fully  Constructed name: %drv%%pth%%fname%%ext%
@ENDLOCAL
pause

Answer 5

Essayez d'exécuter l'exemple ci-dessous afin de sentir comment les variables magiques fonctionnent.

@echo off

SETLOCAL EnableDelayedExpansion

echo Full path and filename: %~f0
echo Drive: %~d0
echo Path: %~p0
echo Drive and path: %~dp0
echo Filename without extension: %~n0
echo Filename with    extension: %~nx0
echo Extension: %~x0

echo date time : %~t0
echo file size: %~z0

ENDLOCAL

Les règles correspondantes sont les suivantes.

%~I         - expands %I removing any surrounding quotes ("")
%~fI        - expands %I to a fully qualified path name
%~dI        - expands %I to a drive letter only
%~pI        - expands %I to a path only
%~nI        - expands %I to a file name only
%~xI        - expands %I to a file extension only
%~sI        - expanded path contains short names only
%~aI        - expands %I to file attributes of file
%~tI        - expands %I to date/time of file
%~zI        - expands %I to size of file
%~$PATH:I   - searches the directories listed in the PATH
               environment variable and expands %I to the
               fully qualified name of the first one found.
               If the environment variable name is not
               defined or the file is not found by the
               search, then this modifier expands to the
               empty string