Qu'est-ce qu'un crochet pre-revprop-change dans SVN et comment le créer?

Question

Je voulais éditer un commentaire de log dans le navigateur de dépôt et j'ai reçu un message d'erreur indiquant qu'il n'y a pas de crochet pre-revprop-change pour le dépôt. En plus d'avoir un nom effrayant, qu'est-ce qu'un crochet pre-revprop-change, et comment puis-je le créer ?

Answer 1

Pour Windows, voici un lien vers un exemple de fichier batch qui ne permet que les modifications du message de journal (et non d'autres propriétés) :

http://ayria.livejournal.com/33438.html

En gros, copiez le code ci-dessous dans un fichier texte et nommez-le pre-revprop-change.bat puis enregistrez-le dans le sous-répertoire \hooks de votre dépôt.

@ECHO OFF
:: Définir tous les paramètres. Même si la plupart ne sont pas utilisés, au cas où vous voudriez ajouter
:: des modifications qui permettent, par exemple, d'éditer l'auteur ou d'ajouter des messages de journal.
set repository=%1
set revision=%2
set userName=%3
set propertyName=%4
set action=%5

:: Autoriser uniquement la modification du message de journal, mais pas de l'auteur, etc.
if /I not "%propertyName%" == "svn:log" goto ERROR_PROPNAME

:: Autoriser uniquement la modification d'un message de journal, pas d'ajout ou de suppression.
if /I not "%action%" == "M" goto ERROR_ACTION

:: Assurez-vous que le nouveau message svn:log n'est pas vide.
set bIsEmpty=true
for /f "tokens=*" %%g in ('find /V ""') do (
set bIsEmpty=false
)
if "%bIsEmpty%" == "true" goto ERROR_EMPTY

goto :eof

:ERROR_EMPTY
echo Les messages svn:log vides ne sont pas autorisés. >&2
goto ERROR_EXIT

:ERROR_PROPNAME
echo Seules les modifications des messages de svn:log sont autorisées. >&2
goto ERROR_EXIT

:ERROR_ACTION
echo Seules les modifications des propriétés de révision de svn:log sont autorisées. >&2
goto ERROR_EXIT

:ERROR_EXIT
exit /b 1

Answer 2

Fondamentalement, il s'agit d'un script qui est lancé avant qu'une propriété non versionnée ne soit modifiée sur le référentiel, afin que vous puissiez gérer plus précisément ce qui se passe sur votre référentiel.

Il existe des modèles dans la distribution SVN pour différents crochets, situés dans le sous-répertoire /hooks (*.tmpl que vous devez modifier et renommer en fonction de votre système d'exploitation, pour activer).

Answer 3

Voici le lien vers la question stack overflow avec de nombreux hooks communs Types communs de hooks subversion, y compris la source originale du hook pre-revprop-change pour Windows qui est également publié ici.

Vous devriez vous y référer car ils pourraient être améliorés avec le temps.

Answer 4

Merci #patmortech

Et j'ai ajouté votre code qui "seul le même utilisateur peut modifier son code".

:: Autoriser uniquement la modification du même utilisateur.
for /f "tokens=*" %%a in ( 
'"%VISUALSVN_SERVER%\bin\svnlook.exe" author -r %revision% %repository%') do ( 
set orgAuthor=%%a
)
if /I not "%userName%" == "%orgAuthor%" goto ERROR_SAME_USER

Answer 5

Pour les utilisateurs de PC : L'extension .bat n'a pas fonctionné pour moi lorsqu'elle a été utilisée sur la machine Windows Server. J'ai utilisé VisualSvn comme Django Reinhardt l'a suggéré, et cela a créé un hook avec une extension .cmd.