numérotation d'un tableau

Question

numérotation d'un tableau

Demandé el 10 de Mai, 2011: Quand la question a-t-elle été
141 affichage: Nombre de visites la question a
2 Réponses: Nombre de réponses aux questions
Résolu: Situation réelle de la question

La sortie doit être en html, utilisez xsl pour sortir la table des matières, le xml est le suivant

<book title="D">
<author>
  <name>abc</name>
</author>

<chapter title="chapter1">
  <section title="section1.1"/>
  <section title="section1.2">
    <section title="section1.2.1"/>
<section title="section1.2.2"/>
  </section>
  <section title="section1.3">
<section title="section1.3.1"/>
  </section>
</chapter>

<chapter title="chapter2"/>

</book>

le résultat est html, comme ceci :

<body>
  <h2>D</h2>
  <p>
     by abc
  </p>
  <h3>Table of contents</h3>
  <ul>
     <li>[1]chapter1
     <ul>
        <li>[1.1]section1.1</li>
        <li>[1.2]section1.2
        <ul>
           <li>[1.2.1]section1.2.1</li>
           <li>[1.2.2]section1.2.2</li>
        </ul>
        </li>
        <li>[1.3]section1.3
        <ul>
           <li>[1.3.1]section1.3.1</li>
        </ul>
        </li>
     </ul>
     </li>
     <li>[2]chapter2</li>
  </ul>
  </body>

Demandé el 10 de Mai, 2011 par ZAWD

Answer 1

2 Réponses

Answer 2

1voto

Dimitre Novatchev Points 147842

UPDATE : Le PO a modifié son XML fourni après que cette solution ait été postée. La solution ci-dessous produit la numérotation correcte souhaitée. Je ne la mets pas à jour pour rattraper la mise à jour de l'OP, car je ne peux pas passer tout mon temps à attendre la prochaine mise à jour.

Le pouvoir de l'utilisation <xsl:number> est que, quelle que soit la mise à jour effectuée sur les valeurs de chaîne des titres, la numérotation produite continue d'être correcte :)

Cette transformation :

<xsl:stylesheet version="1.0"  xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*"/>
        </xsl:copy>
 </xsl:template>

 <xsl:template match="book">
        <body>
            <xsl:apply-templates select="node()|@*"/>
        </body>
 </xsl:template>

 <xsl:template match="book/@title">
        <h2>
            <xsl:value-of select="."/>
        </h2>
 </xsl:template>

 <xsl:template match="author">
        <p>by 
            <xsl:value-of select="name"/>
        </p>
        <h3>Table of Contents</h3>
        <ul>
            <xsl:apply-templates mode="TC"
                 select="following-sibling::*"/>
        </ul>
 </xsl:template>

 <xsl:template mode="TC"
      match="chapter[section]|section[section]">
        <li>
            [<xsl:number level="multiple"
             count="chapter|section"/>] <xsl:text/>
            <xsl:value-of select="@title"/>
            <ul>
                <xsl:apply-templates mode="TC"/>
            </ul>
        </li>
 </xsl:template>

 <xsl:template mode="TC" match=
    "chapter[not(section)]|section[not(section)]">
        <li>
            [<xsl:number level="multiple"
             count="chapter|section"/>] <xsl:text/>
            <xsl:value-of select="@title"/>
        </li>
 </xsl:template>

 <xsl:template match="chapter|section"/>
</xsl:stylesheet>

lorsqu'il est appliqué au document XML fourni :

<book title="D">
    <author>
        <name>abc</name>
    </author>
    <chapter title="chapter1">
        <section title="section1.1"/>
        <section title="section1.2">
            <section title="section1.2.1"/>
            <section title="section1.2.2"/></section>
        <section title="section3">
            <section title="section3.1"/></section>
    </chapter>
    <chapter title="chapter2"/>
</book>

produit le résultat voulu et correct :

<body>
   <h2>D</h2>
   <p>by 
            abc</p>
   <h3>Table of Contents</h3>
   <ul>
      <li>
            [1] chapter1<ul>
            <li>
            [1.1] section1.1</li>
            <li>
            [1.2] section1.2<ul>
                  <li>
            [1.2.1] section1.2.1</li>
                  <li>
            [1.2.2] section1.2.2</li>
               </ul>
            </li>
            <li>
            [1.3] section3<ul>
                  <li>
            [1.3.1] section3.1</li>
               </ul>
            </li>
         </ul>
      </li>
      <li>
            [2] chapter2</li>
   </ul>
</body>

et il est affiché par le navigateur comme :

D

par abc

Table des matières

[1] chapitre1
- [1.1] section1.1
- [1.2] section1.2
  - [1.2.1] section1.2.1
  - [1.2.2] section1.2.2
- [1.3] section3
  - [1.3.1] section3.1
[2] chapitre2

Explication :

Utilisation de <xsl:number> con level="multiple" en comptant les deux chapter y section .

Répondu el 11 de Mai, 2011 par Dimitre Novatchev (147842 Points )

Answer 3

0voto

lwburk Points 29313

Cette feuille de style :

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="book">
        <body>
            <h2><xsl:apply-templates select="@title" /></h2>
            <p>by <xsl:apply-templates select="author/name" /></p>
            <h3>Table of contents</h3>
            <ul>
                <xsl:apply-templates select="chapter" />
            </ul>
        </body>
    </xsl:template>
    <xsl:template match="chapter|section">
        <li><xsl:call-template name="extract-num" /></li>
    </xsl:template>
    <xsl:template match="chapter[child::*]|section[child::*]">
        <li>
            <xsl:call-template name="extract-num" />
            <ul>
                <xsl:apply-templates />
            </ul>
        </li>
    </xsl:template>
    <xsl:template name="extract-num">
        <xsl:value-of select="concat('[', substring(@title, 8), ']', @title)" />
    </xsl:template>
</xsl:stylesheet>

Sur cette entrée :

<book title="D">
    <author>
        <name>abc</name>
    </author>
    <chapter title="chapter1">
        <section title="section1.1" />
        <section title="section1.2">
            <section title="section1.2.1" />
            <section title="section1.2.2" />
        </section>
        <section title="section3">
            <section title="section3.1" />
        </section>
    </chapter>
    <chapter title="chapter2" />
</book>

Produit :

<body>
    <h2>D</h2>
    <p>by abc</p>
    <h3>Table of contents</h3>
    <ul>
        <li>[1]chapter1
            <ul>
                <li>[1.1]section1.1</li>
                <li>[1.2]section1.2
                    <ul>
                        <li>[1.2.1]section1.2.1</li>
                        <li>[1.2.2]section1.2.2</li>
                    </ul>
                </li>
                <li>[3]section3
                    <ul>
                        <li>[3.1]section3.1</li>
                    </ul>
                </li>
            </ul>
        </li>
        <li>[2]chapter2</li>
    </ul>
</body>

Note : Espace blanc ajusté pour le formatage. Si vous avez réellement besoin de l'espace blanc exact fourni dans le résultat demandé, vous devrez le modifier en conséquence.

Répondu el 10 de Mai, 2011 par lwburk (29313 Points )

numérotation d'un tableau

Réponses

D

Table des matières

Questions en vedette

Top Tags

Prograide.com

Powered by:

numérotation d'un tableau

Réponses

D

Table des matières

Questions en vedette

Top Tags

Dans notre réseau

Prograide.com

Powered by: