convertir xml en jsonx en utilisant xslt

Question

Quelqu'un peut-il m'aider à obtenir ce qui suit avec un tableau ? Je dois générer le xsl généralisé XML d'entrée :

<Login>
    <Groups>
        <Group>
            <Name>john</Name>
            <Password/>
        </Group>
        <Group>
            <Name>john</Name>
            <Password/>
        </Group>
    </Groups>
</Login>

Sortie :

<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <json:object name="Login">
        <json:object name="Groups">
            <json:array name="Group">
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"/>
                </json:object>
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"/>
                </json:object>
            </json:array>
        </json:object>
    </json:object>
</json:object>

Answer 1

Solution plus généralisée. Nécessite XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx" xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">
    <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes" />

    <xsl:template match="/">
        <xsl:element name="json:object">
            <xsl:apply-templates />    
        </xsl:element>
    </xsl:template>

    <xsl:template match="*[*]">
        <xsl:param name="nodeName" select="name()" />
        <xsl:variable name="firstNodeName" select="name(*[1])" />

        <xsl:element name="json:object">
            <xsl:if test="$nodeName">
                <xsl:attribute name="name" select="$nodeName" />
            </xsl:if>
            <xsl:choose>
                <xsl:when test="(count(*) > 1) and (every $x in */name() satisfies $x=$firstNodeName)">
                    <xsl:element name="json:array">
                        <xsl:attribute name="name" select="$firstNodeName" />

                        <xsl:apply-templates >
                            <xsl:with-param name="nodeName" select="''" />
                        </xsl:apply-templates>
                    </xsl:element>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates />
                </xsl:otherwise>
            </xsl:choose>
        </xsl:element>
    </xsl:template>

    <xsl:template match="*[not(*)]">
        <xsl:element name="json:string">
            <xsl:attribute name="name">
                <xsl:value-of select="name()" />
            </xsl:attribute>
            <xsl:value-of select="text()" />
        </xsl:element>
    </xsl:template> 
</xsl:stylesheet>

Appliqué à l'exemple XML fourni, il produit le résultat suivant :

<?xml version="1.0" encoding="UTF-8"?>
<json:object xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
    <json:object name="Login">
        <json:object name="Groups">
            <json:array name="Group">
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"></json:string>
                </json:object>
                <json:object>
                    <json:string name="Name">john</json:string>
                    <json:string name="Password"></json:string>
                </json:object>
            </json:array>
        </json:object>
    </json:object>
</json:object>

La solution ci-dessus a été testée sur ce site : http://xslttest.appspot.com/

EDITAR:

every $x in */name() satisfies $x=$firstNodeName est une construction XPATH 2.0 qui vérifie si tous les éléments dans */name() sont égaux à $firstNodeName. Ainsi, toute cette condition signifie en fait qu'il faut vérifier si un nœud a plus d'un enfant avec le même nom - c'est une condition pour vérifier si nous avons à faire à json:array cas.

Answer 2

Vous pouvez essayer le xslt générique ci-dessous :

<?xml version="1.0"?>

<xsl:stylesheet xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

<xsl:output omit-xml-declaration="yes" encoding="UTF-8" indent="yes"/>

<xsl:strip-space elements="*"/>

<!-- Array -->

<xsl:template match="*[*[2]][name(*[1])=name(*[2])]">

<json:object name="{name()}">

<json:array name="{name(*[1])}">

<xsl:apply-templates/>

</json:array>

</json:object>

</xsl:template>

<!-- Array member -->

<xsl:template match="*[parent::*[ name(*[1])=name(*[2]) ]] | /">

<json:object>

<xsl:apply-templates/>

</json:object>

</xsl:template>

<!-- Object -->

<xsl:template match="*">

<json:object name="{name()}">

<xsl:apply-templates/>

</json:object>

</xsl:template>

<!-- String -->

<xsl:template match="*[not(*)]">

<json:string name="{name()}">

<xsl:value-of select="."/>

</json:string>

</xsl:template>

</xsl:stylesheet>

Answer 3

<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:json="http://www.ibm.com/xmlns/prod/2009/jsonx">
<xsl:output indent="yes" encoding="UTF-8" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />
<!-- Array -->
<xsl:template match="*[*[2]][name(*[1])=name(*[2])]">
  <json:object name="{name()}">
    <json:array name="{name(*[1])}">
      <xsl:apply-templates />
    </json:array>
  </json:object>
</xsl:template>
<!-- Array member -->
<xsl:template match="*[parent::*[ name(*[1])=name(*[2]) ]] | /">
  <json:object>
    <xsl:apply-templates />
  </json:object>
</xsl:template>
<!-- Object -->
<xsl:template match="*">
  <json:object name="{name()}">
    <xsl:apply-templates />
  </json:object>
</xsl:template>
<!-- String -->
<xsl:template match="*[not(*)]">
  <json:string name="{name()}">
    <xsl:value-of select="." />
  </json:string>
</xsl:template>
</xsl:stylesheet>