Fichier batch pour supprimer les fichiers de plus de N jours

Question

Je cherche un moyen de supprimer tous les fichiers de plus de 7 jours dans un fichier batch. J'ai fait des recherches sur le Web et j'ai trouvé des exemples comportant des centaines de lignes de code, et d'autres qui nécessitaient l'installation d'utilitaires de ligne de commande supplémentaires pour accomplir cette tâche.

Des choses similaires peuvent être fait en BASH en seulement quelques lignes de code. Il semble que l'on pourrait faire quelque chose d'au moins aussi simple pour les fichiers batch sous Windows. Je cherche une solution qui fonctionne dans une invite de commande Windows standard, sans utilitaires supplémentaires. Je vous prie de ne pas utiliser PowerShell ou Cygwin.

Answer 1

Profitez-en :

forfiles -p "C:\what\ever" -s -m *.* -d <number of days> -c "cmd /c del @path"

Voir forfiles documentation pour plus de détails.

Pour plus d'informations, reportez-vous à Un index A-Z de la ligne de commande de Windows XP .

Si vous n'avez pas forfiles installé sur votre machine, copiez-le depuis n'importe quel Windows Server 2003 à votre machine Windows XP à %WinDir%\system32\ . Cela est possible car l'EXE est entièrement compatible entre Windows Server 2003 et Windows XP.

Les versions ultérieures de Windows et de Windows Server l'installent par défaut.

Pour Windows 7 et les versions plus récentes (y compris Windows 10) :

La syntaxe a un peu changé. Par conséquent, la commande mise à jour est :

forfiles /p "C:\what\ever" /s /m *.* /D -<number of days> /C "cmd /c del @path"

Answer 2

Exécutez ce qui suit commandes :

ROBOCOPY C:\source C:\destination /mov /minage:7
del C:\destination /q

Déplacez tous les fichiers (en utilisant /mov, qui déplace les fichiers et les supprime ensuite, par opposition à /move qui déplace des arbres de fichiers entiers qui sont ensuite supprimés) via robocopy vers un autre emplacement, puis exécutez une commande de suppression sur ce chemin et tout va bien.

De même, si vous avez un répertoire contenant beaucoup de données, vous pouvez utiliser /mir commutateur

Answer 3

Je m'ennuyais un peu et j'ai trouvé ceci, qui contient ma version d'un remplacement d'époque Linux du pauvre, limité à un usage quotidien (pas de rétention de temps) :

7daysclean.cmd

@echo off
setlocal ENABLEDELAYEDEXPANSION
set day=86400
set /a year=day*365
set /a strip=day*7
set dSource=C:\temp

call :epoch %date%
set /a slice=epoch-strip

for /f "delims=" %%f in ('dir /a-d-h-s /b /s %dSource%') do (
    call :epoch %%~tf
    if !epoch! LEQ %slice% (echo DELETE %%f ^(%%~tf^)) ELSE echo keep %%f ^(%%~tf^)
)
exit /b 0

rem Args[1]: Year-Month-Day
:epoch
    setlocal ENABLEDELAYEDEXPANSION
    for /f "tokens=1,2,3 delims=-" %%d in ('echo %1') do set Years=%%d& set Months=%%e& set Days=%%f
    if "!Months:~0,1!"=="0" set Months=!Months:~1,1!
    if "!Days:~0,1!"=="0" set Days=!Days:~1,1!
    set /a Days=Days*day
    set /a _months=0
    set i=1&& for %%m in (31 28 31 30 31 30 31 31 30 31 30 31) do if !i! LSS !Months! (set /a _months=!_months! + %%m*day&& set /a i+=1)
    set /a Months=!_months!
    set /a Years=(Years-1970)*year
    set /a Epoch=Years+Months+Days
    endlocal& set Epoch=%Epoch%
    exit /b 0

USAGE

set /a strip=day*7 : Changer 7 pour le nombre de jours à conserver.

set dSource=C:\temp : Il s'agit du répertoire de départ pour la recherche de fichiers.

NOTES

C'est un code non-destructif, il affichera ce qui se serait passé.

Changement :

if !epoch! LEQ %slice% (echo DELETE %%f ^(%%~tf^)) ELSE echo keep %%f ^(%%~tf^)

à quelque chose comme :

if !epoch! LEQ %slice% del /f %%f

pour que les fichiers soient réellement supprimés

Février L'année bissextile : est codée en dur à 28 jours. Les années bissextiles sont un enfer à ajouter, vraiment. Si quelqu'un a une idée qui n'ajouterait pas 10 lignes de code, allez-y et postez-la pour que je l'ajoute à mon code.

époque : Je n'ai pas pris en compte le temps, comme le besoin est de supprimer les fichiers plus anciens qu'une certaine date, prendre les heures/minutes aurait supprimé les fichiers d'un jour qui était destiné à être conservé.

LIMITATION

époque prend pour acquis que votre format de date courte est AAAA-MM-JJ. Il faudrait l'adapter pour d'autres paramètres ou une évaluation en cours d'exécution (lire sShortTime, configuration liée à l'utilisateur, configurer l'ordre correct des champs dans un filtre et utiliser le filtre pour extraire les données correctes de l'argument).

Ai-je mentionné que je déteste l'auto-formatage de cet éditeur ? Il supprime les lignes vides et le copier-coller est un enfer.

J'espère que cela vous aidera.

Answer 4

forfiles /p "v:" /s /m *.* /d -3 /c "cmd /c del @path"

Vous devriez faire /d -3 (3 jours plus tôt) Cela fonctionne bien pour moi. Ainsi, tous les lots compliqués peuvent être mis à la poubelle. Aussi forfiles ne prennent pas en charge les chemins UNC, il faut donc établir une connexion réseau vers un lecteur spécifique.

Answer 5

Jetez un coup d'œil à mon réponse à un question similaire :

REM del_old.bat
REM usage: del_old MM-DD-YYY
for /f "tokens=*" %%a IN ('xcopy *.* /d:%1 /L /I null') do if exist %%~nxa echo %%~nxa >> FILES_TO_KEEP.TXT
for /f "tokens=*" %%a IN ('xcopy *.* /L /I /EXCLUDE:FILES_TO_KEEP.TXT null') do if exist "%%~nxa" del "%%~nxa"

Cela supprime les fichiers plus anciens qu'une date donnée. Je suis sûr qu'il peut être modifié pour revenir sept jours en arrière à partir de la date actuelle.

mettre à jour : Je remarque que HerbCSO a amélioré le script ci-dessus. Je recommande d'utiliser sa version à la place.