Comment puis-je passer des arguments à un fichier batch ?

Question

J'ai besoin de transmettre un identifiant et un mot de passe à un fichier batch au moment de l'exécution plutôt que de les coder en dur dans le fichier.

Voici à quoi ressemble la ligne de commande :

test.cmd admin P@55w0rd > test-log.txt

Answer 1

Une autre astuce utile consiste à utiliser %* pour signifier "tous". Par exemple :

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

Quand tu cours :

test-command admin password foo bar

le fichier batch ci-dessus sera exécuté :

fake-command /u admin /p password admin password foo bar

La syntaxe est peut-être légèrement erronée, mais c'est l'idée générale.

Answer 2

Voilà comment j'ai fait :

@fake-command /u %1 /p %2

Voici à quoi ressemble la commande :

test.cmd admin P@55w0rd > test-log.txt

En %1 s'applique au premier paramètre, le %2 (et voici la partie délicate) s'applique à la seconde. Vous pouvez avoir jusqu'à 9 paramètres passés de cette manière.

Answer 3

Si vous voulez gérer intelligemment les paramètres manquants, vous pouvez faire quelque chose comme :

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

Answer 4

L'accès aux paramètres du lot peut être simple avec %1, %2, ... %9 ou également %*,
mais seulement si le contenu est simple.

Il n'existe pas de méthode simple pour les contenus complexes comme "&"^& car il n'est pas possible d'accéder à %1 sans produire une erreur.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Les lignes s'étendent jusqu'à

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

Et chaque ligne échoue, car l'une des & est en dehors des guillemets.

Ce problème peut être résolu en lisant depuis un fichier temporaire a a remarqué version du paramètre.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

L'astuce consiste à activer echo on et développer le %1 après un rem (fonctionne également avec %2 .. %* ).
Donc même "&"& pourrait être répercutée sans produire d'erreur, comme on le remarque.

Mais pour être en mesure de rediriger la sortie de la fonction echo on vous avez besoin des deux boucles for.

Les caractères supplémentaires * # sont utilisés pour se prémunir contre des contenus tels que /? (afficherait l'aide pour REM ).
Ou encore, un signe d'insertion ^ en fin de ligne pourrait fonctionner comme un caractère multiligne, même après un caractère de type rem .

Ensuite, en lisant le paramètre rem sortie du fichier, mais avec précaution.
Le FOR /F doit fonctionner avec l'expansion différée désactivée, sinon les contenus avec " !" seraient détruits.
Après avoir supprimé les caractères supplémentaires dans param1 vous l'avez.

Et pour utiliser param1 de manière sûre, activer l'expansion différée.

Answer 5

Yep, et n'oubliez pas d'utiliser des variables comme %%1 lors de l'utilisation de if y for et le gang.

Si vous oubliez le double % vous substituerez alors des arguments de ligne de commande (éventuellement nuls) et vous recevrez des messages d'erreur plutôt déroutants.