Comment obtenir le résultat d'une commande dans une variable sous Windows ?

Question

Je cherche à obtenir le résultat d'une commande en tant que variable dans un script batch Windows (cf. comment obtenir le résultat d'une commande en bash pour l'équivalent en script bash). Une solution qui fonctionne dans un fichier .bat est préférable, mais d'autres solutions de script Windows courantes sont également les bienvenues.

Answer 1

L'humble pour La commande a accumulé quelques capacités intéressantes au fil des ans :

D:\> FOR /F "delims=" %i IN ('date /t') DO set today=%i
D:\> echo %today%
Sat 20/09/2008

Notez que "delims=" écrase les délimiteurs d'espace et de tabulation par défaut de sorte que la sortie de la commande date soit engloutie en une seule fois.

Pour capturer une sortie multi-lignes, il peut toujours s'agir essentiellement d'une seule ligne (en utilisant la variable lf comme délimiteur dans la variable résultante) :

REM NB:in a batch file, need to use %%i not %i
setlocal EnableDelayedExpansion
SET lf=-
FOR /F "delims=" %%i IN ('dir \ /b') DO if ("!out!"=="") (set out=%%i) else (set out=!out!%lf%%%i)
ECHO %out%

Pour capturer une expression pipée, utilisez ^| :

FOR /F "delims=" %%i IN ('svn info . ^| findstr "Root:"') DO set "URL=%%i"

Answer 2

Si vous devez capturer toute la sortie de la commande, vous pouvez utiliser un lot comme celui-ci :

@ECHO OFF
IF NOT "%1"=="" GOTO ADDV
SET VAR=
FOR /F %%I IN ('DIR *.TXT /B /O:D') DO CALL %0 %%I
SET VAR
GOTO END

:ADDV
SET VAR=%VAR%!%1

:END

Toutes les lignes de sortie sont stockées dans des VAR séparés par des " !".

Mais si une sortie console d'une seule ligne est attendue, essayez :

@ECHO off
@SET MY_VAR=
FOR /F %%I IN ('npm prefix') DO @SET "MY_VAR=%%I"

@REM Do something with MY_VAR variable...

@John : y a-t-il une utilité pratique à cela ? Je pense que tu devrais regarder PowerShell ou tout autre langage de programmation capable d'effectuer des tâches de script facilement (Python, Perl, PHP, Ruby).

Answer 3

Pour obtenir le répertoire courant, vous pouvez utiliser ceci :

CD > tmpFile
SET /p myvar= < tmpFile
DEL tmpFile
echo test: %myvar%

Il utilise un fichier temporaire, donc ce n'est pas le plus joli, mais ça marche ! CD' place le répertoire courant dans 'tmpFile', 'SET' charge le contenu de tmpFile.

Voici une solution pour les lignes multiples avec des "tableaux" :

@echo off

rem ---------
rem Obtain line numbers from the file
rem ---------

rem This is the file that is being read: You can replace this with %1 for dynamic behaviour or replace it with some command like the first example i gave with the 'CD' command.
set _readfile=test.txt

for /f "usebackq tokens=2 delims=:" %%a in (`find /c /v "" %_readfile%`) do set _max=%%a
set /a _max+=1
set _i=0
set _filename=temp.dat

rem ---------
rem Make the list
rem ---------

:makeList
find /n /v "" %_readfile% >%_filename%

rem ---------
rem Read the list
rem ---------

:readList
if %_i%==%_max% goto printList

rem ---------
rem Read the lines into the array
rem ---------
for /f "usebackq delims=] tokens=2" %%a in (`findstr /r "\[%_i%]" %_filename%`) do set _data%_i%=%%a
set /a _i+=1
goto readList

:printList
del %_filename%
set _i=1
:printMore
if %_i%==%_max% goto finished
set _data%_i%
set /a _i+=1
goto printMore

:finished

Mais vous devriez peut-être envisager de passer à un autre shell plus puissant ou de créer une application pour ce genre de choses. Cela étend un peu les possibilités des fichiers batch.

Answer 4

Vous devez utiliser le SET avec le paramètre /P et dirigez votre sortie vers elle. Par exemple, voir http://www.ss64.com/nt/set.html . Cela fonctionnera pour CMD, mais pas pour les fichiers .BAT.

D'un commentaire à ce post :

Ce lien contient la commande " Set /P _MyVar=<MyFilename.txt "qui dit qu'il fixera _MyVar à la première ligne de MyFilename.txt . Cela pourrait être être utilisé comme " myCmd > tmp.txt " avec " set /P myVar=<tmp.txt ". Mais cela ne fera que la première ligne de la sortie, pas toute toute la sortie

Answer 5

Exemple pour définir dans la variable d'environnement "V" le fichier le plus récent

FOR /F %I IN ('DIR *.* /O:D /B') DO SET V=%I

dans un fichier batch, vous devez utiliser un double préfixe dans la variable de la boucle :

FOR /F %%I IN ('DIR *.* /O:D /B') DO SET V=%%I