Comment utiliser la structure if - else dans un fichier batch ?

Question

J'ai une question sur la structure if - else dans un fichier batch. Chaque commande s'exécute individuellement, mais je n'ai pas pu utiliser les blocs "if - else" en toute sécurité, de sorte que ces parties de mon programme ne fonctionnent pas. Comment puis-je faire en sorte que ces parties soient exécutées ? Merci.

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )
ELSE IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

ELSE IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  bos olanlar hariç, /e:bos olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )
ELSE IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Answer 1

Votre syntaxe est incorrecte. Vous ne pouvez pas utiliser ELSE IF . Il semble que vous n'en ayez pas vraiment besoin de toute façon. Il suffit d'utiliser plusieurs IF déclarations :

IF %F%==1 IF %C%==1 (
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

IF %F%==1 IF %C%==0 (
    ::moving the file c to d
    move "%sourceFile%" "%destinationFile%"
    )

IF %F%==0 IF %C%==1 (
    ::copying a directory c from d, /s:  bos olanlar hariç, /e:bos olanlar dahil
    xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
    )

IF %F%==0 IF %C%==0 (
    ::moving a directory
    xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
    rd /s /q "%sourceMoveDirectory%"
    )

Grande référence en matière de fichiers batch : http://ss64.com/nt/if.html

Answer 2

Je pense que dans la question et dans certaines réponses, il y a un peu de confusion sur la signification de ce pseudo-code dans DOS : IF A IF B X ELSE Y. Cela ne signifie pas IFA et B) THEN X ELSE Y, mais en fait IF A( IF B THEN X ELSE Y). Si le test de A échoue, alors l'ensemble du if-else interne sera ignoré.

Comme l'une des réponses l'a mentionné, dans ce cas, seul un des tests peut réussir, donc le "else" n'est pas nécessaire, mais bien sûr, cela ne fonctionne que dans cet exemple, ce n'est pas une solution générale pour faire des if-else.

Il existe de nombreuses façons de contourner ce problème. Voici quelques idées, toutes sont assez laides mais hé, c'est (ou du moins c'était) DOS !

@echo off

set one=1
set two=2

REM Example 1

IF %one%_%two%==1_1 (
   echo Example 1 fails
) ELSE IF %one%_%two%==1_2 (
   echo Example 1 works correctly
) ELSE (
    echo Example 1 fails
)

REM Example 2

set test1result=0
set test2result=0

if %one%==1 if %two%==1 set test1result=1
if %one%==1 if %two%==2 set test2result=1

IF %test1result%==1 (
   echo Example 2 fails
) ELSE IF %test2result%==1 (
   echo Example 2 works correctly
) ELSE (
    echo Example 2 fails
)

REM Example 3

if %one%==1 if %two%==1 (
   echo Example 3 fails
   goto :endoftests
)
if %one%==1 if %two%==2 (
   echo Example 3 works correctly
   goto :endoftests
)
echo Example 3 fails
)
:endoftests

Answer 3

AFAIK, vous ne pouvez pas faire un if else en batch comme vous pouvez le faire dans d'autres langages, il doit être imbriqué if 's.

Utilisation de l'imbrication if Votre lot ressemblerait à

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    ) ELSE (
        IF %F%==1 IF %C%==0(
        ::moving the file c to d
        move "%sourceFile%" "%destinationFile%"
        ) ELSE (
            IF %F%==0 IF %C%==1(
            ::copying a directory c from d, /s:  bos olanlar hariç, /e:bos olanlar dahil
            xcopy "%sourceCopyDirectory%" "%destinationCopyDirectory%" /s/e
            ) ELSE (
                IF %F%==0 IF %C%==0(
                ::moving a directory
                xcopy /E "%sourceMoveDirectory%" "%destinationMoveDirectory%"
                rd /s /q "%sourceMoveDirectory%"
                )
            )
        )
    )

ou comme James l'a suggéré, enchaînez vos if mais je pense que la syntaxe correcte est la suivante

IF %F%==1 IF %C%==1(
    ::copying the file c to d
    copy "%sourceFile%" "%destinationFile%"
    )

Answer 4

Voici comment j'ai géré la situation "if else if

if %env%==dev ( 
    echo "dev env selected selected"
) else (
    if %env%==prod (
        echo "prod env selected"
    )
)

Note il ne s'agit pas d'un bloc if-elseif comme dans les autres langages de programmation tels que C++ ou Java, mais il fera ce dont vous avez besoin.

Answer 5

Je crois que vous pouvez utiliser quelque chose comme

if ___ (

do this

) else if ___ (

do this

)