Déplacer une ligne/région vers le haut et le bas dans emacs

Question

Quel est le moyen le plus simple de déplacer une région ou une ligne sélectionnée (s'il n'y a pas de sélection) vers le haut ou le bas dans emacs ? Je cherche la même fonctionnalité que dans Eclipse (limité à M-up, M-down).

Answer 1

Mise à jour : Installer le move-text paquet de Marmalade ou MELPA pour obtenir le code suivant.

Voici ce que j'utilise, qui fonctionne à la fois sur les régions et les lignes individuelles :

(defun move-text-internal (arg)
  (cond
   ((and mark-active transient-mark-mode)
    (if (> (point) (mark))
        (exchange-point-and-mark))
    (let ((column (current-column))
          (text (delete-and-extract-region (point) (mark))))
      (forward-line arg)
      (move-to-column column t)
      (set-mark (point))
      (insert text)
      (exchange-point-and-mark)
      (setq deactivate-mark nil)))
   (t
    (let ((column (current-column)))
      (beginning-of-line)
      (when (or (> arg 0) (not (bobp)))
        (forward-line)
        (when (or (< arg 0) (not (eobp)))
          (transpose-lines arg)
          (when (and (eval-when-compile
                       '(and (>= emacs-major-version 24)
                             (>= emacs-minor-version 3)))
                     (< arg 0))
            (forward-line -1)))
        (forward-line -1))
      (move-to-column column t)))))

(defun move-text-down (arg)
  "Move region (transient-mark-mode active) or current line
  arg lines down."
  (interactive "*p")
  (move-text-internal arg))

(defun move-text-up (arg)
  "Move region (transient-mark-mode active) or current line
  arg lines up."
  (interactive "*p")
  (move-text-internal (- arg)))

(global-set-key [M-S-up] 'move-text-up)
(global-set-key [M-S-down] 'move-text-down)

Answer 2

Une ligne peut être déplacée en utilisant lignes de transposition lié à C-x C-t . Je ne sais pas pour les régions, par contre.

J'ai trouvé ce elisp snippet qui fait ce que vous voulez, sauf que vous devez changer les liens.

(defun move-text-internal (arg)
   (cond
    ((and mark-active transient-mark-mode)
     (if (> (point) (mark))
            (exchange-point-and-mark))
     (let ((column (current-column))
              (text (delete-and-extract-region (point) (mark))))
       (forward-line arg)
       (move-to-column column t)
       (set-mark (point))
       (insert text)
       (exchange-point-and-mark)
       (setq deactivate-mark nil)))
    (t
     (beginning-of-line)
     (when (or (> arg 0) (not (bobp)))
       (forward-line)
       (when (or (< arg 0) (not (eobp)))
            (transpose-lines arg))
       (forward-line -1)))))

(defun move-text-down (arg)
   "Move region (transient-mark-mode active) or current line
  arg lines down."
   (interactive "*p")
   (move-text-internal arg))

(defun move-text-up (arg)
   "Move region (transient-mark-mode active) or current line
  arg lines up."
   (interactive "*p")
   (move-text-internal (- arg)))

(global-set-key [\M-\S-up] 'move-text-up)
(global-set-key [\M-\S-down] 'move-text-down)

Answer 3

Vous devriez essayer drag-stuff !

Il fonctionne exactement comme eclipse Alt + Up / Down pour les lignes individuelles, ainsi que pour les lignes de régions sélectionnées !

En plus de cela, il vous permet de déplacer les mots avec Alt + Left / Right
C'est exactement ce que vous recherchez ! Et il est même disponible auprès du Dépôt ELPA !

Les autres solutions n'ont jamais fonctionné pour moi. Certaines d'entre elles étaient boguées (transposer des lignes tout en changeant leur ordre, wtf ?) et certaines déplaçaient exactement la région sélectionnée, laissant les parties non sélectionnées des lignes sur leurs positions. Mais drag-stuff fonctionne exactement comme dans eclipse !

Et bien plus encore ! Vous pouvez essayer de sélectionner une région et d'utiliser Alt + Left / Right ! Ceci transposera la région sélectionnée d'un caractère vers la gauche ou la droite. Incroyable !

Pour l'activer globalement, il suffit d'exécuter ceci :

(drag-stuff-global-mode)

Answer 4

J'ai écrit quelques fonctions interactives pour déplacer des lignes vers le haut/bas :

;; move line up
(defun move-line-up ()
  (interactive)
  (transpose-lines 1)
  (previous-line 2))

(global-set-key [(control shift up)] 'move-line-up)

;; move line down
(defun move-line-down ()
  (interactive)
  (next-line 1)
  (transpose-lines 1)
  (previous-line 1))

(global-set-key [(control shift down)] 'move-line-down)

Les combinaisons de touches sont du style IntelliJ IDEA, mais vous pouvez utiliser ce que vous voulez. Je devrais probablement implémenter quelques fonctions qui opèrent sur les régions aussi bien.

Answer 5

Il y a une entrée dans le wiki d'emacs juste pour cela :

http://www.emacswiki.org/emacs/MoveLine

Pour les régions en mouvement :

http://www.emacswiki.org/emacs/MoveRegion