Convertir XLS en CSV en ligne de commande

Question

Comment convertir un fichier XLS en fichier CSV en ligne de commande Windows.

La machine est équipée de Microsoft Office 2000. Je suis ouvert à l'installation d'OpenOffice si cela n'est pas possible avec Microsoft Office.

Answer 1

Ouvrez Notepad, créez un fichier appelé XlsToCsv.vbs et collez-y ceci :

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Error! Please specify the source path and the destination. Usage: XlsToCsv SourcePath.xls Destination.csv"
    Wscript.Quit
End If
Dim oExcel
Set oExcel = CreateObject("Excel.Application")
Dim oBook
Set oBook = oExcel.Workbooks.Open(Wscript.Arguments.Item(0))
oBook.SaveAs WScript.Arguments.Item(1), 6
oBook.Close False
oExcel.Quit
WScript.Echo "Done"

Ensuite, à partir d'une ligne de commande, allez dans le dossier où vous avez enregistré le fichier .vbs et exécutez-le :

XlsToCsv.vbs [sourcexlsFile].xls [destinationcsvfile].csv

Pour ce faire, il faut toutefois qu'Excel soit installé sur la machine sur laquelle vous vous trouvez.

Answer 2

Une version légèrement modifiée de la réponse de ScottF, qui ne nécessite pas de chemins de fichiers absolus :

if WScript.Arguments.Count < 2 Then
    WScript.Echo "Please specify the source and the destination files. Usage: ExcelToCsv <xls/xlsx source file> <csv destination file>"
    Wscript.Quit
End If

csv_format = 6

Set objFSO = CreateObject("Scripting.FileSystemObject")

src_file = objFSO.GetAbsolutePathName(Wscript.Arguments.Item(0))
dest_file = objFSO.GetAbsolutePathName(WScript.Arguments.Item(1))

Dim oExcel
Set oExcel = CreateObject("Excel.Application")

Dim oBook
Set oBook = oExcel.Workbooks.Open(src_file)

oBook.SaveAs dest_file, csv_format

oBook.Close False
oExcel.Quit

J'ai renommé le script ExcelToCsv, puisque ce script n'est pas du tout limité aux xls. xlsx Fonctionne très bien, comme on pouvait s'y attendre.

Testé avec Office 2010.

Answer 3

Une petite extension du groovy VB script de ScottF : ce fichier batch va parcourir en boucle les fichiers .xlsx d'un répertoire et les convertir en fichiers *.csv :

FOR /f "delims=" %%i IN ('DIR *.xlsx /b') DO ExcelToCSV.vbs "%%i" "%%i.csv"

Note : Vous pouvez changer l'extension .xlsx en .xls et le nom du script ExcelToCSV en XlsToCsv.

Answer 4

Et avec PowerShell ?

Le code devrait ressembler à ceci, mais il n'a pas été testé.

$xlCSV = 6
$Excel = New-Object -Com Excel.Application 
$Excel.visible = $False 
$Excel.displayalerts=$False 
$WorkBook = $Excel.Workbooks.Open("YOUDOC.XLS") 
$Workbook.SaveAs("YOURDOC.csv",$xlCSV) 
$Excel.quit()

Voici un post expliquant comment l'utiliser

Comment utiliser Windows PowerShell pour automatiser Microsoft Excel ?

Answer 5

Pourquoi ne pas écrire le vôtre ?

Je vois sur votre profil que vous avez au moins une certaine expérience en C#/.NET. Je créerais une application console Windows et utiliserais un lecteur Excel gratuit pour lire votre/vos fichier(s) Excel. J'ai utilisé Lecteur de données Excel disponible à partir de CodePlex sans aucun problème (une chose intéressante : ce lecteur ne nécessite pas l'installation d'Excel). Vous pouvez appeler votre application console depuis la ligne de commande.

Si vous vous trouvez coincé, postez ici et je suis sûr que vous obtiendrez de l'aide.