Commande(s) batch Windows pour lire la première ligne d'un fichier texte

Question

Comment lire la première ligne d'un fichier texte à l'aide d'un fichier batch Windows ? Le fichier étant volumineux, je ne veux traiter que la première ligne.

Answer 1

euh ? imo ceci est beaucoup plus simple

  set /p texte=< file.txt  
  echo %texte%

Answer 2

Voici un fichier batch à usage général pour imprimer le haut de la page n des lignes d'un fichier comme celui de GNU head au lieu d'une seule ligne.

@echo off

if [%1] == [] goto usage
if [%2] == [] goto usage

call :print_head %1 %2
goto :eof

REM
REM print_head
REM Prints the first non-blank %1 lines in the file %2.
REM
:print_head
setlocal EnableDelayedExpansion
set /a counter=0

for /f ^"usebackq^ eol^=^

^ delims^=^" %%a in (%2) do (
        if "!counter!"=="%1" goto :eof
        echo %%a
        set /a counter+=1
)

goto :eof

:usage
echo Usage: head.bat COUNT FILENAME

Par exemple :

Z:\>head 1 "test file.c"
; this is line 1

Z:\>head 3 "test file.c"
; this is line 1
    this is line 2
line 3 right here

Il ne compte pas actuellement les lignes vides. Il est également soumis à la restriction de longueur de ligne des fichiers de lot de 8 Ko.

Answer 3

Euh, les gars...

C:\>findstr /n . c:\boot.ini | findstr ^1:

1:[boot loader]

C:\>findstr /n . c:\boot.ini | findstr ^3:

3:default=multi(0)disk(0)rdisk(0)partition(1)\WINNT

C:\>

Answer 4

Vous pourriez essayer :

@echo off

for /f %%a in (sample.txt) do (
  echo %%a
  exit /b
)

modifier Ou, disons que vous avez quatre colonnes de données et que vous voulez partir de la cinquième ligne vers le bas, essayez ceci :

@echo off

for /f "skip=4 tokens=1-4" %%a in (junkl.txt) do (
  echo %%a %%b %%c %%d
)

Answer 5

Merci à thetalkingwalnut pour la réponse. http://stackoverflow.com/questions/130116/dos-batch-commands-to-read-first-line-from-text-file#130154 J'ai trouvé la solution suivante :

@echo off
for /f "delims=" %%a in ('type sample.txt') do (
echo %%a
exit /b
)