Comment puis-je vérifier la taille d'un fichier dans un script batch Windows ?

Question

Je veux avoir un fichier batch qui vérifie ce que le filesize est d'un dossier.

Si elle est supérieure à %somany% kbytes, il devrait rediriger avec GOTO vers un autre endroit.

Exemple :

[check for filesize]
IF %file% [filesize thing Bigger than] GOTO No
echo Great! Your filesize is smaller than %somany% kbytes.
pause
exit
:no
echo Um... You have a big filesize.
pause
exit

Answer 1

Si le nom du fichier est utilisé comme un paramètre du fichier batch, tout ce dont vous avez besoin est %~z1 (1 signifie premier paramètre)

Si le nom du fichier n'est pas un paramètre, vous pouvez faire quelque chose comme :

@echo off
setlocal
set file="test.cmd"
set maxbytesize=1000

FOR /F "usebackq" %%A IN ('%file%') DO set size=%%~zA

if %size% LSS %maxbytesize% (
    echo.File is ^< %maxbytesize% bytes
) ELSE (
    echo.File is ^>= %maxbytesize% bytes
)

Answer 2

%~z1 s'étend à la taille du premier argument du fichier batch. Voir

C:\> call /?

y

C:\> if /?

Un exemple simple :

@ECHO OFF
SET SIZELIMIT=1000
SET FILESIZE=%~z1

IF %FILESIZE% GTR %SIZELIMIT% Goto No

ECHO Great! Your filesize is smaller than %SIZELIMIT% kbytes.
PAUSE
GOTO :EOF

:No
ECHO Um ... You have a big filesize.
PAUSE
GOTO :EOF

Answer 3

Si votre %file% est un paramètre d'entrée, vous pouvez utiliser %~zN où N est le numéro du paramètre.

Par exemple, un test.bat contenant

@echo %~z1

affichera la taille du premier paramètre, donc si vous utilisez " test myFile.txt ", il affichera la taille du fichier correspondant.

Answer 4

Un autre exemple

  FOR %I in (file1.txt) do @ECHO %~zI

Answer 5

Comme d'habitude, vous pouvez utiliser VBScript......

Set objFS = CreateObject("Scripting.FileSystemObject")
Set wshArgs = WScript.Arguments
strFile = wshArgs(0)
WScript.Echo objFS.GetFile(strFile).Size & " bytes"

Enregistrer sous filesize.vbs et entrer dans la ligne de commande :

C:\test>cscript /nologo filesize.vbs file.txt
79 bytes

Utilisez un for boucle (en lot) pour obtenir le résultat du retour.