Utilisation d'une seule clé pour flymake et flyspell

Question

J'utilise flymake avec pyflakes pour vérifier mon code python et flyspell pour vérifier mes chaînes de caractères et mes commentaires. Je veux avoir une fonction qui passe à l'erreur suivante, ou qui affiche des informations sur l'erreur si je suis actuellement sur une erreur. Comment dois-je écrire cette fonction ?

Answer 1

Ce code fournit une fonctionnalité qui vous fait sauter à l'erreur suivante, et si c'est une erreur flymake, affiche des informations pour celle-ci, si c'est une erreur flyspell, elle la corrige pour vous. Si vous ne voulez pas l'auto-correction, décommentez la ligne qui fait appel à 'my-flyspell-message et supprimez la ligne qui précède et qui appelle 'flyspell-auto-correct-word - et vous obtiendrez un message indiquant que le mot est mal orthographié.

La première ligne lie ce dernier au keybinding C-c n . Pour plus d'informations sur les clés de liaison, voir la page d'information Fixations des clés .

(global-set-key (kbd "C-c n") 'my-display-error-or-next-error)
(defun my-display-error-or-next-error ()
  "display information for current error, or go to next one"
  (interactive)
  (when (or (not (my-at-flymake-error))
            (not (my-at-flyspell-error)))
    ;; jump to error if not at one
    (my-goto-next-error))

  (cond ((my-at-flymake-error)
         ;; if at flymake error, display menu
         (flymake-display-err-menu-for-current-line))
        ((my-at-flyspell-error)
         ;; if at flyspell error, fix it
         (call-interactively 'flyspell-auto-correct-word)
         ;; or, uncomment the next line to just get a message
         ;; (my-flyspell-message)
         )))

(defun my-at-flyspell-error ()
  "return non-nill if at flyspell error"
  (some 'flyspell-overlay-p (overlays-at (point))))

(defun my-at-flymake-error ()
  "return non-nil if at flymake error"
  (let* ((line-no             (flymake-current-line-no))
         (line-err-info-list  (nth 0 (flymake-find-err-info flymake-err-info line-no))))
    line-err-info-list))

(defun my-goto-next-error ()
  "jump to next flyspell or flymake error"
  (interactive)
  (let* ((p (point))
         (spell-next-error-function '(lambda ()
                                 (forward-word) (forward-char)
                                 (flyspell-goto-next-error)))
         (spell-pos (save-excursion
                      (funcall spell-next-error-function)
                      (point)))
         (make-pos (save-excursion
                     (flymake-goto-next-error)
                     (point))))
    (cond ((or (and (< p make-pos) (< p spell-pos))
               (and (> p make-pos) (> p spell-pos)))
           (funcall (if (< make-pos spell-pos)
                        'flymake-goto-next-error
                      spell-next-error-function)))
          ((< p make-pos)
           (flymake-goto-next-error))

          ((< p spell-pos)
           (funcall spell-next-error-function)))))

(defun my-flyspell-message ()
  (interactive)
  (let ((word (thing-at-point 'word)))
    (set-text-properties 0 (length word) nil word)
    (message "Missspelled word: %s" word)))