J'ai besoin de montrer des données Excel sur une page web ou un document Word présentable ?

Question

J'ai des résultats d'enquête qui sont bien formatés dans Excel. J'ai ensuite besoin de montrer ces résultats individuellement avec les rubriques sur un document Word ou une page Web présentable. Y a-t-il un moyen de le faire ?

Par exemple :

colonne 1 - colonne 2

résultat 1 - résultat 1

résultat 2 - résultat 2

a

colonne 1

premier résultat

colonne 2

premier résultat

colonne 1

résultat 2

colonne 2

résultat 2

Désolé si cela n'a pas de sens.

Gracias

Answer 1

Il semble que vous deviez utiliser "Mail Merge" à partir de Word, puis indiquer la feuille de calcul Excel comme source de données.

Answer 2

Votre question ne contient pas beaucoup d'informations, mais il semble que vous pourriez utiliser une macro pour transformer vos données. J'ai écrit une macro rapide qui prend les données dans le format que vous avez présenté et les sort comme vous l'avez spécifié.

J'utiliserais la macro ci-dessous pour créer une nouvelle feuille de calcul dans Excel, puis la manipuler ou la coller dans Word si nécessaire. Sans plus d'informations, il n'y a rien de plus à dire.

**Input**
Column A      Column B
Result A1     Result B1
Result A2     Result B2
**Output**
Column A
Result A1
Column B
Result B1
Column A
Result A2
Column B
Result B2

Voici la macro :

' Transforms the current sheet
' This method takes columns and rows and outputs a
' single This is not a transpose method, but similar.
Public Sub TransformSheet()
    Dim SourceSheet As Worksheet
    Dim ResultSheet As Worksheet
    Dim iSourceColumn As Long, iSourceRow As Long
    Dim iResultColumn As Long, iResultRow As Long
    Dim iHeaderRow As Long
    Dim UseCopyPaste As Boolean
    ' Change source and result sheets as necessary
    Set SourceSheet = ActiveSheet
    Set ResultSheet = ActiveWorkbook.Sheets("Sheet2")
    ' Options
    UseCopyPaste = True
    iHeaderRow = 1
    iResultColumn = 1
    iResultRow = 1
    ' Main Loop
    For iSourceRow = 2 To SourceSheet.UsedRange.Rows.Count
        For iSourceColumn = 1 To SourceSheet.UsedRange.Columns.Count
            If UseCopyPaste Then
                ' Header Column
                SourceSheet.Cells(iHeaderRow, iSourceColumn).Copy
                ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll
                iResultRow = iResultRow + 1
                ' Result  Column
                SourceSheet.Cells(iSourceRow, iSourceColumn).Copy
                ResultSheet.Cells(iResultRow, iResultColumn).PasteSpecial xlPasteAll
                iResultRow = iResultRow + 1
            Else
                ' Header Column
                ResultSheet.Cells(iResultRow, iResultColumn) = _
                    SourceSheet.Cells(iHeaderRow, iSourceColumn).Value
                iResultRow = iResultRow + 1
                ' Result Column
                ResultSheet.Cells(iResultRow, iResultColumn) = _
                    SourceSheet.Cells(iSourceRow, iSourceColumn).Value
                iResultRow = iResultRow + 1
            End If
        Next iSourceColumn
    Next iSourceRow
End Sub