Supprimer tous les fichiers et dossiers d'un répertoire

Question

Je veux avoir un fichier batch qui supprimera tous les dossiers et fichiers de mon dossier cache pour mon kit d'outils sans fil.

Actuellement, j'ai les éléments suivants :

cd "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS"
del *.db

Cela supprimera tous les fichiers .db dans mon fichier RMS mais je veux supprimer tous les éléments de ce répertoire. Comment puis-je le faire ?

Answer 1

Utilisez :

• Créer un fichier batch

• Copiez le texte ci-dessous dans le fichier batch

  set folder="C:\test"
  cd /d %folder%
  for /F "delims=" %%i in ('dir /b') do (rmdir "%%i" /s/q || del "%%i" /s/q)

Il va supprimer tous les fichiers y les dossiers.

Answer 2

del *.* au lieu de del *.db . Cela va tout enlever.

Answer 3

IF EXIST "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" (
    rmdir "C:\Users\tbrollo\j2mewtk\2.5.2\appdb\RMS" /s /q
)

Cela supprimera tout ce qui se trouve dans le dossier (et le dossier lui-même).

Answer 4

del *.* ne supprimera que les fichiers, mais pas les sous-répertoires. Pour effacer le contenu d'un répertoire, vous pouvez utiliser ce script :

@echo off
setlocal enableextensions
if {%1}=={} goto :HELP
if {%1}=={/?} goto :HELP
goto :START

:HELP
echo Usage: %~n0 directory-name
echo.
echo Empties the contents of the specified directory,
echo WITHOUT CONFIRMATION. USE EXTREME CAUTION!
goto :DONE

:START
pushd %1 || goto :DONE
rd /q /s . 2> NUL
popd

:DONE
endlocal

Le site pushd change dans le répertoire dont vous voulez supprimer les enfants. Ensuite, lorsque rd demande de supprimer le répertoire courant et tous les sous-répertoires, la suppression des sous-répertoires réussit, mais la suppression du répertoire courant échoue - parce que nous sommes dedans. Cela produit une erreur qui 2> NUL avale. (2 étant le flux d'erreur).

Answer 5

Essayez ce qui suit ; cela fonctionne pour moi.

J'ai une application qui déverse des données dans mon " C:\tmp "et ce qui suit fonctionne le mieux pour moi. Il ne demande même pas Oui o Non pour supprimer les données. J'ai établi un programme pour qu'il s'exécute toutes les 5 minutes.

cd "C:\tmp"

del *.* /Q