Comment tester si un exécutable existe dans le %PATH% à partir d'un fichier batch Windows ?

Question

Je cherche un moyen simple de tester si un exécutable existe dans la variable d'environnement PATH à partir d'un fichier batch Windows.

L'utilisation d'outils externes non fournis par l'OS n'est pas autorisée. La version minimale de Windows requise est Windows XP.

Answer 1

Windows Vista et les versions ultérieures sont livrés avec un programme appelé where.exe qui recherche les programmes dans le chemin. Cela fonctionne comme suit :

D:\>where notepad
C:\Windows\System32\notepad.exe
C:\Windows\notepad.exe

D:\>where where
C:\Windows\System32\where.exe

Pour l'utilisation dans un fichier batch, vous pouvez utiliser la commande /q qui définit simplement ERRORLEVEL et ne produit aucun résultat.

where /q myapplication
IF ERRORLEVEL 1 (
    ECHO The application is missing. Ensure it is installed and placed in your PATH.
    EXIT /B
) ELSE (
    ECHO Application exists. Let's go!
)

Ou une version abrégée simple (mais moins lisible) qui imprime le message et quitte votre application :

where /q myapplication || ECHO Cound not find app. && EXIT /B

Answer 2

for %%X in (myExecutable.exe) do (set FOUND=%%~$PATH:X)
if defined FOUND ...

Si vous en avez besoin pour différentes extensions, il suffit d'itérer sur PATHEXT :

set FOUND=
for %%e in (%PATHEXT%) do (
  for %%X in (myExecutable%%e) do (
    if not defined FOUND (
      set FOUND=%%~$PATH:X
    )
  )
)

C'est peut-être que where existe aussi déjà sur les anciennes versions de Windows, mais je n'y ai pas accès, donc je ne peux pas le dire. Sur ma machine, ce qui suit fonctionne également :

where myExecutable

et retourne avec un code de sortie non nul s'il n'a pas pu être trouvé. Dans un lot, vous voudrez probablement aussi rediriger la sortie vers NUL mais

Gardez à l'esprit

Parsing en lot ( .bat ) et sur la ligne de commande diffère (parce que les fichiers batch ont %0 - %9 ), vous devez donc doubler le % là. Sur la ligne de commande, ce n'est pas nécessaire, donc les variables sont juste %X .

Answer 3

Voici une solution simple qui tente d'exécuter l'application et gère toute erreur. ensuite .

file.exe /?  2> NUL
IF NOT %ERRORLEVEL%==9009 ECHO file.exe exists in path

Le code d'erreur 9009 signifie généralement que le fichier n'a pas été trouvé.

Le seul inconvénient est que file.exe est effectivement exécutée si elle est trouvée (ce qui dans certains cas n'est pas souhaitable).

Answer 4

Cela peut se faire par substitution de paramètres.

%~$PATH:1

Cela renvoie le chemin complet du nom de fichier exécutable dans %1, sinon une chaîne vide.

Cela ne fonctionne pas avec les variables définies par l'utilisateur. Donc si le nom du fichier exécutable n'est pas un paramètre de votre script, alors vous avez besoin d'une sous-routine. Par exemple :

call :s_which app.exe
if not "%_path%" == "" (
  "%_path%"
)

goto :eof

:s_which
  setlocal
  endlocal & set _path=%~$PATH:1
  goto :eof

Voir http://ss64.com/nt/syntax-args.html

Answer 5

@echo off
set found=
set prog=cmd.exe
for %%i in (%path%) do if exist %%i\%prog% set found=%%i
echo "%found%"
if "%found%"=="" ....