Comment exécuter des macros Excel à partir d'une ligne de commande ou d'un fichier batch ?

Question

J'ai une macro Excel VBA qui doit être exécutée lorsque j'accède au fichier à partir d'un fichier batch, mais pas à chaque fois que je l'ouvre (d'où le fait de ne pas utiliser l'événement d'ouverture de fichier). Existe-t-il un moyen d'exécuter la macro à partir de la ligne de commande ou du fichier batch ? Je ne suis pas familier avec une telle commande.

Supposons un environnement Windows NT.

Answer 1

Vous pouvez lancer Excel, ouvrir le classeur et exécuter la macro à partir d'un fichier VBScript.

Copiez le code ci-dessous dans le Bloc-notes.

Mettez à jour le ' MonWorkbook.xls et MyMacro paramètres.

Enregistrez-le avec une extension vbs et exécutez-le.

Option Explicit

On Error Resume Next

ExcelMacroExample

Sub ExcelMacroExample() 

  Dim xlApp 
  Dim xlBook 

  Set xlApp = CreateObject("Excel.Application") 
  Set xlBook = xlApp.Workbooks.Open("C:\MyWorkbook.xls", 0, True) 
  xlApp.Run "MyMacro"
  xlApp.Quit 

  Set xlBook = Nothing 
  Set xlApp = Nothing 

End Sub 

La ligne clé qui exécute la macro est :

xlApp.Run "MyMacro" (Ma macro)

Answer 2

La façon la plus simple de le faire est de :

1) Lancez Excel à partir de votre fichier batch pour ouvrir le classeur contenant votre macro :

EXCEL.EXE /e "c:\YourWorkbook.xls"

2) Appelez votre macro à partir de l'écran du classeur. Workbook_Open événement, tel que :

Private Sub Workbook_Open()
    Call MyMacro1          ' Call your macro
    ActiveWorkbook.Save    ' Save the current workbook, bypassing the prompt
    Application.Quit       ' Quit Excel
End Sub

Cette opération permet de renvoyer le contrôle à votre fichier batch pour qu'il effectue d'autres traitements.

Answer 3

Vous pourriez écrire un vbscript pour créer une instance d'excel via la méthode createobject(), puis ouvrir le classeur et exécuter la macro. Vous pouvez soit appeler le vbscript directement, soit appeler le vbscript à partir d'un fichier batch.

Voici une ressource sur laquelle je suis tombé par hasard : http://www.codeguru.com/forum/showthread.php?t=376401

Answer 4

Si vous êtes plus à l'aise pour travailler dans Excel/VBA, utilisez l'événement d'ouverture et testez l'environnement : ayez un fichier de signal, une entrée de registre ou une variable d'environnement qui contrôle ce que fait l'événement d'ouverture.

Vous pouvez créer le fichier/réglage à l'extérieur et tester à l'intérieur (utilisez GetEnviromentVariable pour les env-vars) et tester facilement. J'ai écrit du VBScript mais les similitudes avec le VBA me causent plus d'angoisse que de facilité

[plus]

Si je comprends bien le problème, vous voulez utiliser une feuille de calcul normalement la plupart du temps, mais la faire fonctionner par lot et faire quelque chose d'extra/différent. Vous pouvez ouvrir la feuille à partir de la ligne de commande excel.exe, mais vous ne pouvez pas contrôler ce qu'elle fait si elle ne sait pas où elle se trouve. L'utilisation d'une variable d'environnement est relativement simple et permet de tester facilement la feuille de calcul.

Pour clarifier, utilisez la fonction ci-dessous pour examiner l'environnement. Dans un module déclarer :

Private Declare Function GetEnvVar Lib "kernel32" Alias "GetEnvironmentVariableA" _
    (ByVal lpName As String, ByVal lpBuffer As String, ByVal nSize As Long) As Long

Function GetEnvironmentVariable(var As String) As String
Dim numChars As Long

    GetEnvironmentVariable = String(255, " ")

    numChars = GetEnvVar(var, GetEnvironmentVariable, 255)

End Function

Dans l'événement d'ouverture du classeur (comme les autres) :

Private Sub Workbook_Open()
    If GetEnvironmentVariable("InBatch") = "TRUE" Then
        Debug.Print "Batch"
    Else
        Debug.Print "Normal"
    End If
End Sub

Ajoutez le code actif le cas échéant. Dans le fichier batch, utilisez

set InBatch=TRUE

Answer 5

Au lieu de comparer directement les chaînes (VB ne les trouvera pas égales puisque GetEnvironmentVariable renvoie une chaîne de longueur 255), écrivez ceci :

Private Sub Workbook_Open()     
    If InStr(1, GetEnvironmentVariable("InBatch"), "TRUE", vbTextCompare) Then
        Debug.Print "Batch"  
        Call Macro
    Else    
        Debug.Print "Normal"     
    End If 

End Sub